dev-build/osc: new package, add 1.27.1

Signed-off-by: Dominik George <nik+gentoo@squirrel.land>

dev-build/osc/Manifest

@@ -0,0 +1 @@
+DIST osc-1.27.1.tar.gz 515776 BLAKE2B 46f8d5f9b92193e49e266e4c7bfccbcaaae46e6e32ac499f070c63eeb2ae76c7e49fde2018086ce007f700ab23aba51340707e435eb5aedc5c2cdd876c617a88 SHA512 3ddcef2f19ac915baa3ceb8fd3c7d72aecf046a907fcc52b26a6ecace843df15f7f877dc62356b88ec1ec7ea852640e2ff1cc0ced165c807ee140a617af6655d

dev-build/osc/metadata.xml

@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="person">
+    <name>Dominik George</name>
+    <email>nik+gentoo@squirrel.land</email>
+  </maintainer>
+  <upstream>
+    <bugs-to>https://github.com/openSUSE/osc/issues</bugs-to>
+    <remote-id type="github">openSUSE/osc</remote-id>
+  </upstream>
+</pkgmetadata>

dev-build/osc/osc-1.27.1.ebuild

@@ -0,0 +1,46 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{12..14} )
+DISTUTILS_SINGLE_IMPL=1
+DISTUTILS_USE_PEP517=setuptools
+
+inherit distutils-r1
+
+DESCRIPTION="Command Line Interface to work with an Open Build Service"
+
+HOMEPAGE="
+	https://openbuildservice.org/
+	https://github.com/openSUSE/osc
+"
+
+SRC_URI="
+	https://github.com/openSUSE/${PN}/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz
+"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	app-arch/rpm[python,${PYTHON_SINGLE_USEDEP}]
+	$(python_gen_cond_dep '
+		dev-python/cryptography[${PYTHON_USEDEP}]
+		dev-python/ruamel-yaml[${PYTHON_USEDEP}]
+		dev-python/urllib3[${PYTHON_USEDEP}]
+	')
+"
+BDEPEND="
+	test? (
+		dev-vcs/git
+		dev-util/diffstat
+	)
+"
+
+EPYTEST_DESELECT=(
+	# test broken inside venv
+	tests/test_doc_plugins.py::TestPopProjectPackageFromArgs::test_plugin_locations
+)
+distutils_enable_tests pytest