media-sound/Tauon: add 8.2.3

Signed-off-by: David Roman <davidroman96@gmail.com>

media-sound/Tauon/Manifest

@@ -1,2 +1,3 @@
 DIST Tauon-8.2.1.tar.gz 1666328 BLAKE2B fd7b55e5a221da75ac53e4ced3140e038ae2e2ca93d0604af8903c513cb0cf26f395813a454d5af91db3c96195f06e720adc6a98ebbbaf3d674cd4adc8464322 SHA512 3bf00e45eee02527a38928fd6d6686d125d25f02b93dcfebba19b38d2a8b2b9a3de553a9c40fe65d10ca85eb1b572fdb0115a0344a4170b0c652364a31e8e3ef
 DIST Tauon-8.2.2.tar.gz 1666194 BLAKE2B 39e8a10c3db748a1e2279157a8f5313621418815da0446b234bd48cb54b5efe87333cfdd778d4ae034e27df568f67326f7a9f798f8664630dd01d83a3d8ef35a SHA512 5ab87595b523e0302db3f1d648616621390488336e3a443a9a8e56952eca8a783aa9dec3a4342f9e76664131c10b2dd64b125c42e25186f648e2b61d09df0e5d
+DIST Tauon-8.2.3.tar.gz 1728107 BLAKE2B 2f53c700dd3b2b121daa44ee94c4e437ad1ae21d3eb3911a4bba110ce7255e555fa0532803c2aac709df4b21f2d6ca6773df1ba5ae69ced225cedc9dbaff8f7a SHA512 4bf8113565f2c5b767725c65bcf79b54f382a9a72efbf62b0fa3d7ca100b9fa242d83086c4af65f28bccdaf702a6935ef1079e77148b3d5c1857c068d62f6617

media-sound/Tauon/Tauon-8.2.3.ebuild

@@ -0,0 +1,108 @@
+# Copyright 2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PLOCALES="cs de es fr_FR hu id it ja_JP nb_NO pl pt pt_BR pt_PT ru sv tr zh_CN"
+
+PYTHON_COMPAT=( python3_{12..14} )
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+
+inherit desktop distutils-r1 optfeature plocale xdg
+
+DESCRIPTION="The desktop music player of today!"
+HOMEPAGE="https://tauonmusicbox.rocks/"
+
+if [[ ${PV} == *9999 ]]; then
+	EGIT_SUBMODULES=()
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/Taiko2k/${PN}"
+else
+	SRC_URI="https://github.com/Taiko2k/Tauon/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="GPL-3"
+SLOT="0"
+
+PHAZOR_DEPS="
+	dev-libs/miniaudio
+	media-libs/flac:=
+	media-libs/game-music-emu
+	media-libs/libopenmpt
+	media-libs/opus
+	media-libs/opusfile
+	media-libs/libsamplerate
+	media-libs/libvorbis
+	media-sound/mpg123
+	media-sound/wavpack
+	sci-libs/kissfft[-cpu_flags_x86_sse]
+"
+
+DEPEND="
+	dev-python/aiohttp[${PYTHON_USEDEP}]
+	dev-python/beautifulsoup4[${PYTHON_USEDEP}]
+	dev-python/musicbrainzngs[${PYTHON_USEDEP}]
+	dev-python/natsort[${PYTHON_USEDEP}]
+	dev-python/pillow[${PYTHON_USEDEP}]
+	dev-python/pysdl3[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/setproctitle[${PYTHON_USEDEP}]
+	dev-python/send2trash[${PYTHON_USEDEP}]
+	dev-python/unidecode[${PYTHON_USEDEP}]
+	media-video/ffmpeg
+	media-libs/mutagen[${PYTHON_USEDEP}]
+	media-libs/sdl3-image
+
+	${PHAZOR_DEPS}
+"
+
+RDEPEND="
+	${DEPEND}
+
+	dev-libs/libayatana-appindicator
+	media-sound/mpg123-base
+	x11-libs/libnotify
+"
+
+BDEPEND="sys-devel/gettext"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-7.9.0-phazor-build.patch"
+	"${FILESDIR}/${PN}-8.1.0-fix-locale-path.patch"
+)
+
+src_compile() {
+	distutils-r1_src_compile
+
+	build_locale() {
+		msgfmt -o "locale/${1}/LC_MESSAGES/tauon.mo" "locale/${1}/LC_MESSAGES/tauon.po" || die
+	}
+
+	plocale_for_each_locale build_locale
+}
+
+python_install() {
+	distutils-r1_python_install
+
+	install_locale() {
+		insinto "/usr/share/locale/${1}/LC_MESSAGES"
+		doins "locale/${1}/LC_MESSAGES/tauon.mo"
+	}
+
+	plocale_for_each_locale install_locale
+
+	sed -i 's/Exec=tauon/Exec=tauonmb/g' extra/tauonmb.desktop || die
+	domenu extra/tauonmb.desktop
+	doicon -s scalable extra/tauonmb.svg
+
+}
+
+pkg_postinst() {
+	optfeature "Chinese searches support" app-i18n/opencc[python]
+	optfeature "last fm support" dev-python/pylast
+	optfeature "PLEX support" dev-python/plexapi
+	optfeature "Spotify support" dev-python/tekore
+
+	xdg_pkg_postinst
+}