net-misc/giara: add 1.1.0

Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo@sysrq.in>

net-misc/giara/Manifest

@@ -1 +1,2 @@
 DIST giara-1.0.1.tar.bz2 152103 BLAKE2B 615724317b29b1ba0743edbd9bc0190ec1647ef61aff02aa833d6fe19c375afda3bcc8293f38cb067d31d71b8e269ffca510320f275ebca9b803d9096f470608 SHA512 75cc9ce9fb2baea5919c8da4f1a18d73602a753ee92e9ad660814b5c97f879b04474f338f2b4c91336fae9b1469e78bfc68ccb78ddd17af459276bd13042c6ac
+DIST giara-1.1.0.tar.bz2 160995 BLAKE2B bbaaeccd05ca51236447faec1839c87adbd4acf0ef24cf5f644aaa8e8d254b916ee948c96bd469ed0fd0214f416c09bf63384b41ed78694ae63b840f8f6df97d SHA512 60dee316f5fdd93787cac05844436aa53649f7304528f086dbdfa7f486b2adbcaf1f3d4440bd6bc9bdfea33acf2504ffc567200110b4f90df29758b146559fa6

net-misc/giara/giara-1.1.0.ebuild

@@ -0,0 +1,70 @@
+# Copyright 2022-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..11} )
+inherit gnome2-utils meson python-single-r1 xdg
+
+DESCRIPTION="An app for Reddit"
+HOMEPAGE="https://giara.gabmus.org https://gitlab.gnome.org/World/giara"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://gitlab.gnome.org/World/${PN}.git"
+else
+	SRC_URI="https://gitlab.gnome.org/World/${PN}/-/archive/${PV}/${P}.tar.bz2"
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="GPL-3+"
+SLOT="0"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	dev-libs/glib:2
+	dev-libs/gobject-introspection
+	>=gui-libs/gtk-4.10:4[introspection]
+	gui-libs/gtksourceview:5[introspection]
+	>=gui-libs/libadwaita-1.3:1[introspection]
+	$(python_gen_cond_dep '
+		dev-python/beautifulsoup4[${PYTHON_USEDEP}]
+		dev-python/mistune[${PYTHON_USEDEP}]
+		dev-python/pillow[${PYTHON_USEDEP}]
+		dev-python/praw[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+	')
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-util/blueprint-compiler
+	sys-devel/gettext
+"
+
+src_prepare() {
+	default
+
+	# fix broken shebang
+	sed "s|py_installation.full_path()|'${PYTHON}'|" -i bin/meson.build || die
+}
+
+# skip AppStream test
+src_test() {
+:
+}
+
+src_install() {
+	meson_src_install
+	python_optimize
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}