gui-wm/phoc: add 0.52.0

Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo@sysrq.in>

gui-wm/phoc/Manifest

@@ -4,3 +4,5 @@ DIST phoc-0.49.0.tar.xz 778512 BLAKE2B e99808c9a1b6c49fc65b959e983fb9bbafa8e00d4
 DIST phoc-0.49.0.tar.xz.asc 833 BLAKE2B e9543a52aa5fa12f6e69131993fe3275a68144a713e4de52a7d85d632a75e48574e04320df87a305ff1c25ac1360d8a4087a90e7f3893f13d9865e6e6161c1a5 SHA512 9632ad05ac42a83ab1942985b580cd569cc8250286616b5df56d526cfbf9aff656672cf3d98fba3606d5448f31a394a816e98b7dcf5f47aeeb7c5156bf234461
 DIST phoc-0.50.0.tar.xz 784008 BLAKE2B 03f49c43512b6d3a36aa813fa766318136d6fc6889886fb005b6725b6bf4f46445907feb066caf6a83f54d01270cdd115538f759d8c13e107ddf574c0784fa63 SHA512 4b33651d0df483a741230192284b3365ba2d42aed60ea77b279ebcc9768fbc0b0ae23f2a386299cb0ebde47f118ee2b9e7381a414d3f37fef3716a34814f9192
 DIST phoc-0.50.0.tar.xz.asc 833 BLAKE2B 9eb24f408effa4b0e39309ee8a613dde868e54f085491204f2fcf7e420b0458904648e76feab4ffd24dfbb3612913271659df2a0babce7b201aa441a8b81c7fc SHA512 c8824e95d91d45a73c30edcf8a38e13f401fa0824fbb03ab2d3e308e467c4dcb3408e04478e3aaf2b5df3b612953c496d6758a8c8584a1e3ea6810ee658da637
+DIST phoc-0.52.0.tar.xz 792672 BLAKE2B be23c4f3f8aa35959ac7eb66d8b0c1fdd79a2d20fb19644b71cc85404e4a58734a27eddb91a92b06026e53d77595f5e866222662b044cbade946dd7d1ee06e4c SHA512 089b2bb4e80c0ad5b0fd98f2599f9644f00a172e771234a825af62b3462f81bfb8d0123c33faf4bb8f7379f8faebaa0b77cc710ef57d0d72520b8e3ac0295b32
+DIST phoc-0.52.0.tar.xz.asc 833 BLAKE2B d3676b6b161af4e5e063c078fc0d1ab7cb5bd43f77b0a02d4ea1ac2b95e06663cd79e0e6bc55ef8ca327d00dfae08eb494f7d097f520749963fdff8c62598f4b SHA512 a77920010488cf56473f231bbe625e648c4f9ec968f4e3d99638b3a900db4767a73e357005e5e514926de28be9e8b8d464a7c4ee2ac27ff094ba7806862ff675

gui-wm/phoc/phoc-0.52.0.ebuild

@@ -0,0 +1,128 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome2-utils meson verify-sig virtualx xdg
+
+DESCRIPTION="Wayland compositor for mobile phones"
+HOMEPAGE="https://gitlab.gnome.org/World/Phosh/phoc"
+SRC_URI="https://sources.phosh.mobi/releases/${PN}/${P}.tar.xz
+	verify-sig? ( https://sources.phosh.mobi/releases/${PN}/${P}.tar.xz.asc )
+"
+
+LICENSE="|| ( GPL-3+ MIT ) GPL-3+ LGPL-2.1+ MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+IUSE="dtrace gtk-doc man sysprof test"
+RESTRICT="!test? ( test )"
+
+WLROOTS_RDEPEND="
+	>=dev-libs/libinput-1.27.0:=
+	>=dev-libs/libliftoff-0.4
+	>=dev-libs/wayland-1.23.1
+	media-libs/libdisplay-info:=
+	media-libs/libglvnd
+	>=media-libs/mesa-24.1.0_rc1[opengl]
+	media-libs/vulkan-loader
+	sys-apps/hwdata
+	sys-auth/seatd:=
+	x11-base/xwayland
+	x11-libs/cairo
+	>=x11-libs/libdrm-2.4.122
+	x11-libs/libxcb:=
+	x11-libs/pango
+	>=x11-libs/pixman-0.43.0
+	x11-libs/xcb-util-errors
+	x11-libs/xcb-util-renderutil
+	x11-libs/xcb-util-wm
+	virtual/libudev:=
+"
+WLROOTS_DEPEND="
+	dev-util/vulkan-headers
+	>=x11-libs/libxkbcommon-1.8.0
+"
+WLROOTS_BDEPEND="
+	dev-util/glslang
+"
+
+RDEPEND="${WLROOTS_RDEPEND}
+	>=dev-libs/glib-2.80:2
+	>=dev-libs/gmobile-0.6.0
+	dev-libs/libinput:=
+	>=dev-libs/wayland-1.23.1
+	>=gnome-base/gnome-desktop-3.26:3=
+	gnome-base/gsettings-desktop-schemas
+	>=x11-libs/pixman-0.43.4
+	x11-libs/libxcb:=
+	x11-libs/libxkbcommon
+	dtrace? ( dev-debug/systemtap )
+	sysprof? (
+		>=dev-util/sysprof-capture-48:4
+		>=dev-util/sysprof-48
+	)
+"
+DEPEND="${WLROOTS_DEPEND}
+	${RDEPEND}
+	sysprof? ( >=dev-util/sysprof-common-48 )
+	test? ( x11-wm/mutter )
+"
+BDEPEND="${WLROOTS_BDEPEND}
+	dev-libs/glib:2
+	>=dev-libs/wayland-protocols-1.41
+	dev-util/wayland-scanner
+	sys-devel/gettext
+	gtk-doc? ( dev-util/gi-docgen )
+	man? ( dev-python/docutils )
+	verify-sig? ( sec-keys/openpgp-keys-phosh )
+"
+
+VERIFY_SIG_OPENPGP_KEY_PATH="/usr/share/openpgp-keys/phosh.asc"
+
+src_prepare() {
+	default
+
+	cd subprojects/wlroots-* || die
+	eapply "${S}"/subprojects/packagefiles/wlroots
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature dtrace)
+		$(meson_feature sysprof)
+		$(meson_use gtk-doc gtk_doc)
+		$(meson_use man)
+		$(meson_use test tests)
+		-Ddefault_library=static
+		-Dembed-wlroots=enabled
+		-Dxwayland=enabled
+	)
+	meson_src_configure
+}
+
+src_test() {
+	local -x LC_ALL="C.UTF-8"
+	virtx meson_src_test
+}
+
+src_install() {
+	meson_src_install --skip-subprojects wlroots
+
+	if use gtk-doc; then
+		mkdir -p "${ED}"/usr/share/gtk-doc/html/ || die
+		mv "${ED}"/usr/share/doc/${PN}-${SLOT} "${ED}"/usr/share/gtk-doc/html/ || die
+	fi
+
+	newbin tools/auto-maximize phoc-auto-maximize
+	newbin tools/scale-to-fit phoc-scale-to-fit
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}