media-sound/mopidy: add 4.0.1

Signed-off-by: bakedsnake <bakedsnake@vagrantz.xyz>

media-sound/mopidy/Manifest

@@ -1 +1,2 @@
 DIST mopidy-3.4.2.tar.gz 449837 BLAKE2B d1d906cd1a35a1714124bb4a6f4186231efdcaed832252e735c2e4690340c6b9c4c56cbeff588e395b6902b1ea1be8e1a52035580f65c3b95ba103b6feaa0873 SHA512 3c6a8ca328377176f4a985741d306e0d544d194d7f6fdb4cb115b1b61fa70644f9c3c7086eb45e6ca49feb8b6210a96386ca83c18f48bdba53963fc7fcf38883
+DIST mopidy-4.0.1.tar.gz 508894 BLAKE2B 29642ca6c642488bb73ad23ca1dc96f64cc1e84a216ca69b2db8abba110ebf3ccdf4e4503f1d2761dd1ccfec3a667597388ca2c077a5dc49ce5bcef48eab0598 SHA512 4bbca6cdc250a85f9baff10d0908df29fd9bf82c48caf2262f2b2c19d46996ca7d81e49f03fceefe667dff4ce7c6706700997698588d650fd89309281904dbf6

media-sound/mopidy/mopidy-4.0.1.ebuild

@@ -0,0 +1,78 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{12..15} )
+
+inherit distutils-r1
+
+DESCRIPTION="An extensible music server written in Python"
+HOMEPAGE="https://mopidy.com/"
+SRC_URI="https://github.com/mopidy/mopidy/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+
+BDEPEND="dev-python/setuptools-scm"
+# https://docs.mopidy.com/stable/installation/manual/
+RDEPEND="
+	dev-python/gst-python[${PYTHON_USEDEP}]
+	dev-python/pykka[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/tornado[${PYTHON_USEDEP}]
+	media-plugins/gst-plugins-meta[mp3,ogg,flac]
+	dev-libs/gobject-introspection
+	x11-libs/cairo
+"
+
+DEPEND="
+	${RDEPEND}
+	test? (
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-python/cyclopts[${PYTHON_USEDEP}]
+		dev-python/pydantic[${PYTHON_USEDEP}]
+		dev-python/faker[${PYTHON_USEDEP}]
+		dev-python/polyfactory[${PYTHON_USEDEP}]
+		dev-python/dirty-equals[${PYTHON_USEDEP}]
+		dev-python/responses[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=( "${PN}" )
+EPYTEST_LOAD_VIA_ENV=1
+
+distutils_enable_tests pytest
+
+EPYTEST_IGNORE=(
+	# Upstream uses a mix of pytest and unittest
+	# Since most tests are pytest, let's ignore unittest tests
+	tests/test_mixer.py
+	tests/_app/test_deps.py
+	tests/_app/test_extensions.py
+	tests/_exts/http/test_server.py
+	tests/_exts/http/test_handlers.py
+
+	# these test depend on dev-python/httpx which has been deprecated
+	tests/_exts/stream/test_http.py
+	tests/_exts/stream/test_library.py
+	tests/_exts/stream/test_playback.py
+)
+
+EPYTEST_DESELECT=(
+	# Broken test due to network-sandbox
+	tests/_exts/http/test_events.py
+	tests/_exts/http/test_network.py
+	tests/_exts/http/test_events.py
+
+	# https://github.com/mopidy/mopidy/commit/784073e52af58c51a11ad89eeb793a72ecc01c92
+	tests/_exts/m3u/test_translator.py::test_path_to_uri[test.mp3-file-file:///test.mp3]
+)
+
+src_configure() {
+	export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+	distutils-r1_src_configure
+}