media-gfx/swayimg: new package, add 1.11

Signed-off-by: Mykyta Holubakha <hilobakho@gmail.com>

media-gfx/swayimg/Manifest

@@ -0,0 +1 @@
+DIST swayimg-1.11.tar.gz 390650 BLAKE2B 5ab45417f214d63ac36f6f28d89848a0f0d55e8fe3051f003838206c80501d67be7ba3d9cdeb0e23c8a305778586665d2800c72ff857adf5acb550cccd0a014c SHA512 6a9722b101c4e4cc2bee5c18f9ca46d2602460521dfd0fe05da1c0d631d4dbaae492c6d27cb38d759d4f4ef10159897f952bb23499ac26123f2b5d646152bbf8

media-gfx/swayimg/metadata.xml

@@ -0,0 +1,13 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>hilobakho@gmail.com</email>
+	</maintainer>
+	<upstream>
+		<remote-id type="github">artemsen/swayimg</remote-id>
+	</upstream>
+	<use>
+		<flag name="jpegxl">Enable support for JPEG XL image format</flag>
+	</use>
+</pkgmetadata>

media-gfx/swayimg/swayimg-1.11.ebuild

@@ -0,0 +1,55 @@
+# Copyright 2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson
+
+DESCRIPTION="A lightweight image viewer for Wayland display servers"
+HOMEPAGE="https://github.com/artemsen/swayimg"
+SRC_URI="https://github.com/artemsen/swayimg/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	dev-libs/json-c
+	dev-libs/wayland
+	media-libs/fontconfig
+	media-libs/freetype
+	x11-libs/libxkbcommon
+	exif? ( media-libs/libexif )
+	gif? ( media-libs/giflib )
+	heif? ( media-libs/libheif )
+	jpeg? ( media-libs/libjpeg-turbo )
+	jpegxl? ( media-libs/libjxl )
+	png? ( media-libs/libpng )
+	svg? ( gnome-base/librsvg )
+	tiff? ( media-libs/tiff )
+	webp? ( media-libs/libwebp )"
+DEPEND="${RDEPEND}
+	dev-libs/wayland-protocols"
+BDEPEND="dev-util/wayland-scanner"
+
+IUSE="+exif +gif heif +jpeg jpegxl +png svg tiff webp bash-completion zsh-completion"
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature exif)
+		$(meson_feature gif)
+		$(meson_feature heif)
+		$(meson_feature jpeg)
+		$(meson_feature jpegxl jxl)
+		$(meson_feature png)
+		$(meson_feature svg)
+		$(meson_feature tiff)
+		$(meson_feature webp)
+		$(meson_feature bash-completion bash)
+		$(meson_feature zsh-completion zsh)
+		-Dversion=${PV}
+		-Ddesktop=true
+		-Dman=true
+	)
+	meson_src_configure
+}