mirror of
https://github.com/gentoo-mirror/guru.git
synced 2026-07-19 20:13:01 -04:00
bb0aae8ad3
Python 3.10 target is scheduled for removal in Gentoo: https://public-inbox.gentoo.org/gentoo-dev/e6ca9f1f4ababb79ab2a3d005c39b483c3ecef6e.camel@gentoo.org/ Sphinx 8.2.0 already dropped support for CPython 3.10 and PyPy 3.10, leading to multiple CI failures in ::guru. We can safely remove this target, because GURU is "experimental" and does not have stable keywords. Let's not remove "pypy3" right now because a) There are not many packages using it. b) So we can see which packages supported PyPy 3.10, and test them with PyPy 3.11. Closes: https://github.com/gentoo/guru/pull/291 Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo@sysrq.in>
82 lines
1.6 KiB
Bash
82 lines
1.6 KiB
Bash
# Copyright 1999-2024 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
PYTHON_COMPAT=( python3_{11..13} )
|
|
|
|
inherit autotools prefix python-any-r1 xdg
|
|
|
|
DESCRIPTION="A limit-removing enhanced-resolution Doom source port based on Chocolate Doom"
|
|
HOMEPAGE="https://github.com/fabiangreffrath/crispy-doom"
|
|
SRC_URI="https://github.com/fabiangreffrath/${PN}/archive/${P}.tar.gz"
|
|
|
|
S="${WORKDIR}"/${PN}-${P}
|
|
|
|
LICENSE="BSD GPL-2+"
|
|
SLOT="0"
|
|
KEYWORDS="~amd64 ~x86"
|
|
IUSE="doc fluidsynth libsamplerate +midi png truecolor vorbis zlib"
|
|
REQUIRE_USE="fluidsynth? ( midi )"
|
|
|
|
DEPEND="
|
|
media-libs/libsdl2[video]
|
|
media-libs/sdl2-mixer[fluidsynth?,midi?,vorbis?]
|
|
media-libs/sdl2-net
|
|
libsamplerate? ( media-libs/libsamplerate )
|
|
png? ( media-libs/libpng:= )
|
|
zlib? ( sys-libs/zlib )"
|
|
RDEPEND="${DEPEND}"
|
|
# ${PYTHON_DEPS} for bash-completion
|
|
BDEPEND="
|
|
${PYTHON_DEPS}
|
|
doc? ( ${PYTHON_DEPS} )"
|
|
|
|
DOCS=(
|
|
"AUTHORS"
|
|
"ChangeLog"
|
|
"NEWS.md"
|
|
"NOT-BUGS.md"
|
|
"PHILOSOPHY.md"
|
|
"README.md"
|
|
"README.Music.md"
|
|
"README.Strife.md"
|
|
)
|
|
|
|
PATCHES=(
|
|
${FILESDIR}/${P}-cflags.patch
|
|
)
|
|
|
|
src_prepare() {
|
|
default
|
|
|
|
hprefixify src/d_iwad.c
|
|
|
|
eautoreconf
|
|
}
|
|
|
|
src_configure() {
|
|
econf \
|
|
--enable-bash-completion \
|
|
$(use_enable doc) \
|
|
--disable-fonts \
|
|
--disable-icons \
|
|
$(use_with libsamplerate) \
|
|
$(use_with png libpng) \
|
|
--enable-sdl2mixer \
|
|
--enable-sdl2net \
|
|
$(use_with fluidsynth) \
|
|
$(use_enable truecolor) \
|
|
$(use_with zlib) \
|
|
--disable-zpool
|
|
}
|
|
|
|
src_install() {
|
|
emake DESTDIR="${D}" install
|
|
|
|
# Remove redundant documentation files
|
|
rm -r "${ED}/usr/share/doc/"* || die
|
|
|
|
einstalldocs
|
|
}
|