mirror of
https://github.com/gentoo-mirror/guru.git
synced 2026-07-15 01:53:25 -04:00
bb0aae8ad3
Python 3.10 target is scheduled for removal in Gentoo: https://public-inbox.gentoo.org/gentoo-dev/e6ca9f1f4ababb79ab2a3d005c39b483c3ecef6e.camel@gentoo.org/ Sphinx 8.2.0 already dropped support for CPython 3.10 and PyPy 3.10, leading to multiple CI failures in ::guru. We can safely remove this target, because GURU is "experimental" and does not have stable keywords. Let's not remove "pypy3" right now because a) There are not many packages using it. b) So we can see which packages supported PyPy 3.10, and test them with PyPy 3.11. Closes: https://github.com/gentoo/guru/pull/291 Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo@sysrq.in>
58 lines
1.4 KiB
Bash
58 lines
1.4 KiB
Bash
# Copyright 2019-2024 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
PYTHON_COMPAT=( python3_{11..12} pypy3 )
|
|
DISTUTILS_USE_PEP517=setuptools
|
|
inherit databases distutils-r1 edo
|
|
|
|
DESCRIPTION="Implementation of the psycopg2 module using cffi. Compatible with Psycopg 2.5."
|
|
HOMEPAGE="
|
|
https://pypi.org/project/psycopg2cffi/
|
|
https://github.com/chtd/psycopg2cffi
|
|
"
|
|
SRC_URI="https://github.com/chtd/${PN}/archive/refs/tags/${PV}.tar.gz -> ${P}.gh.tar.gz"
|
|
|
|
LICENSE="LGPL-3+"
|
|
SLOT="0"
|
|
KEYWORDS="~amd64"
|
|
|
|
DEPEND="dev-db/postgresql:="
|
|
RDEPEND="
|
|
${DEPEND}
|
|
dev-python/six[${PYTHON_USEDEP}]
|
|
"
|
|
BDEPEND="
|
|
$(python_gen_cond_dep 'dev-python/cffi[${PYTHON_USEDEP}]' 'python*')
|
|
test? ( ${DATABASES_DEPEND[postgres]} )
|
|
"
|
|
|
|
PATCHES=( "${FILESDIR}"/${P}-include-tests.patch )
|
|
|
|
EPYTEST_DESELECT=(
|
|
# hang
|
|
tests/psycopg2_tests/test_cancel.py::CancelTests::test_async_cancel
|
|
# fail
|
|
tests/psycopg2_tests/test_dates.py::FromTicksTestCase::test_date_value_error_sec_59_99
|
|
tests/psycopg2_tests/test_types_basic.py::TypesBasicTests::testEmptyArray
|
|
)
|
|
|
|
distutils_enable_tests pytest
|
|
|
|
python_test() {
|
|
cd "${T}" || die
|
|
epytest --pyargs ${PN}
|
|
}
|
|
|
|
src_test() {
|
|
local -x PSYCOPG2_TESTDB_HOST="localhost"
|
|
local -x PSYCOPG2_TESTDB_PORT="55432"
|
|
local -x PSYCOPG2_TESTDB_USER="postgres"
|
|
epostgres --start ${PSYCOPG2_TESTDB_PORT}
|
|
edo createdb -h ${PSYCOPG2_TESTDB_HOST} -p ${PSYCOPG2_TESTDB_PORT} -U postgres psycopg2_test
|
|
|
|
distutils-r1_src_test
|
|
epostgres --stop
|
|
}
|