mirror of
https://github.com/gentoo-mirror/guru.git
synced 2026-10-12 17:51:11 -04:00
ingenarel (NeoJesus)
d56f4baa37
as per the coding style guide: https://projects.gentoo.org/qa/policy-guide/ebuild-format.html#pg0101 if it previously used [ ${PV} ... ] it uses [[ ${PV} ... ]] now if it previously used [[ ${PV} = b ]] or [ ${PV} = b ], it uses [[ ${PV} == b ]] now the changes were generated using these two commands: ``` find -name '*.ebuild' -exec sed -i -E \ 's|([^[])\[+(\s+)(\S*\$\S*PV\S*)(\s+)(\S+)(\s+)(\S+)(\s+)\]+([^]])|\1\[\[\2\3\4\5\6\7\8\]\]\9|g' \ {} \+ find -name '*.ebuild' -exec sed -i -E \ 's|\[(\s+)(\S*\$\S*PV\S*)(\s+)==?(\s+)(\S+)(\s+)\]|\[\1\2\3==\4\5\6\]|g' \ {} \+ ``` this is aimed to be a series of commits meant to replace all instance of POSIX [ ... ] to bash's [[ ... ]], to make guru up to date with the coding style guide this process is divided up into a series of commits in order to make review and testing more easy Signed-off-by: ingenarel (NeoJesus) <ingenarel_neojesus@disroot.org> Part-of: https://codeberg.org/gentoo/guru/pulls/6 Signed-off-by: Michał Górny <mgorny@gentoo.org>
72 lines
1.6 KiB
Bash
72 lines
1.6 KiB
Bash
# Copyright 2020-2023 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
inherit meson xdg-utils
|
|
|
|
DESCRIPTION="S* Floating Window Bar"
|
|
HOMEPAGE="https://github.com/LBCrion/sfwbar"
|
|
if [[ "${PV}" == 9999 ]] ; then
|
|
inherit git-r3
|
|
EGIT_REPO_URI="https://github.com/LBCrion/${PN}"
|
|
else
|
|
SRC_URI="https://github.com/LBCrion/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
|
|
KEYWORDS="~amd64"
|
|
fi
|
|
LICENSE="GPL-3"
|
|
SLOT="0"
|
|
|
|
IUSE="+menu X mpd pulseaudio alsa network networkmanager iwd bluetooth notification man idleinhibit bsdctl"
|
|
|
|
COMMON_DEPEND="
|
|
dev-libs/glib:2
|
|
dev-libs/json-c:=
|
|
dev-libs/wayland
|
|
gui-libs/gtk-layer-shell
|
|
>=x11-libs/gtk+-3.22.0:3[introspection,wayland]
|
|
X? ( x11-libs/libxkbcommon )
|
|
mpd? ( media-libs/libmpdclient )
|
|
pulseaudio? ( media-libs/libpulse[glib] )
|
|
alsa? ( media-libs/alsa-lib )
|
|
"
|
|
RDEPEND="${COMMON_DEPEND}
|
|
virtual/freedesktop-icon-theme
|
|
x11-libs/cairo
|
|
x11-libs/gdk-pixbuf
|
|
x11-libs/pango
|
|
"
|
|
DEPEND="${COMMON_DEPEND}
|
|
>=dev-libs/wayland-protocols-1.17
|
|
"
|
|
BDEPEND="dev-util/wayland-scanner"
|
|
|
|
src_configure() {
|
|
local emesonargs=(
|
|
$(meson_feature alsa)
|
|
$(meson_feature mpd)
|
|
$(meson_feature pulseaudio pulse)
|
|
$(meson_feature X xkb)
|
|
$(meson_feature network)
|
|
$(meson_feature networkmanager nm)
|
|
$(meson_feature iwd)
|
|
$(meson_feature menu appmenu)
|
|
$(meson_feature bluetooth bluez)
|
|
$(meson_feature bsdctl)
|
|
$(meson_feature notification ncenter)
|
|
$(meson_feature notification idle)
|
|
$(meson_feature man build-docs)
|
|
$(meson_feature idleinhibit)
|
|
)
|
|
|
|
meson_src_configure
|
|
}
|
|
|
|
pkg_postinst() {
|
|
xdg_icon_cache_update
|
|
}
|
|
|
|
pkg_postrm() {
|
|
xdg_icon_cache_update
|
|
}
|