mirror of
https://github.com/gentoo-mirror/guru.git
synced 2026-07-08 22:52:59 -04:00
bb0aae8ad3
Python 3.10 target is scheduled for removal in Gentoo: https://public-inbox.gentoo.org/gentoo-dev/e6ca9f1f4ababb79ab2a3d005c39b483c3ecef6e.camel@gentoo.org/ Sphinx 8.2.0 already dropped support for CPython 3.10 and PyPy 3.10, leading to multiple CI failures in ::guru. We can safely remove this target, because GURU is "experimental" and does not have stable keywords. Let's not remove "pypy3" right now because a) There are not many packages using it. b) So we can see which packages supported PyPy 3.10, and test them with PyPy 3.11. Closes: https://github.com/gentoo/guru/pull/291 Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo@sysrq.in>
71 lines
1.7 KiB
Bash
71 lines
1.7 KiB
Bash
# Copyright 1999-2025 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
PYTHON_COMPAT=( python3_{11..13} )
|
|
DISTUTILS_USE_PEP517=setuptools
|
|
inherit click-app distutils-r1 pypi
|
|
|
|
DESCRIPTION="Suite of tools and fixtures to manage daemons for testing"
|
|
HOMEPAGE="
|
|
https://pypi.org/project/pifpaf/
|
|
https://github.com/jd/pifpaf
|
|
"
|
|
|
|
LICENSE="Apache-2.0"
|
|
SLOT="0"
|
|
KEYWORDS="~amd64"
|
|
|
|
RDEPEND="
|
|
dev-python/click[${PYTHON_USEDEP}]
|
|
dev-python/daiquiri[${PYTHON_USEDEP}]
|
|
dev-python/fixtures[${PYTHON_USEDEP}]
|
|
dev-python/jinja2[${PYTHON_USEDEP}]
|
|
dev-python/packaging[${PYTHON_USEDEP}]
|
|
dev-python/psutil[${PYTHON_USEDEP}]
|
|
$(python_gen_cond_dep '
|
|
|| (
|
|
dev-python/pyxattr[${PYTHON_USEDEP}]
|
|
dev-python/xattr[${PYTHON_USEDEP}]
|
|
)'
|
|
)
|
|
"
|
|
BDEPEND="
|
|
dev-python/setuptools-scm[${PYTHON_USEDEP}]
|
|
test? (
|
|
app-admin/consul
|
|
app-admin/vault
|
|
dev-db/etcd[server]
|
|
dev-db/postgresql[server]
|
|
dev-db/redis
|
|
dev-python/httpbin[${PYTHON_USEDEP}]
|
|
dev-python/requests[${PYTHON_USEDEP}]
|
|
dev-python/testtools[${PYTHON_USEDEP}]
|
|
net-misc/kafka-bin
|
|
net-misc/memcached
|
|
net-misc/rabbitmq-server
|
|
sys-cluster/ceph
|
|
virtual/mysql[server]
|
|
)
|
|
"
|
|
|
|
EPYTEST_DESELECT=(
|
|
# Drivers need fixes
|
|
pifpaf/tests/test_drivers.py::TestDrivers::test_influxdb
|
|
pifpaf/tests/test_drivers.py::TestDrivers::test_mongodb
|
|
pifpaf/tests/test_drivers.py::TestDrivers::test_redis_sentinel
|
|
)
|
|
|
|
distutils_enable_tests pytest
|
|
|
|
click-app_enable_completions pifpaf
|
|
|
|
export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
|
|
|
|
python_test() {
|
|
# RabbitMQ wrappers installed to /usr/sbin require to be run as root.
|
|
local -x PATH="${BUILD_DIR}/install${EPREFIX}/usr/bin:${BROOT}/usr/libexec/rabbitmq:${PATH}"
|
|
epytest
|
|
}
|