mirror of
https://github.com/gentoo-mirror/guru.git
synced 2026-07-09 15:13:31 -04:00
bb0aae8ad3
Python 3.10 target is scheduled for removal in Gentoo: https://public-inbox.gentoo.org/gentoo-dev/e6ca9f1f4ababb79ab2a3d005c39b483c3ecef6e.camel@gentoo.org/ Sphinx 8.2.0 already dropped support for CPython 3.10 and PyPy 3.10, leading to multiple CI failures in ::guru. We can safely remove this target, because GURU is "experimental" and does not have stable keywords. Let's not remove "pypy3" right now because a) There are not many packages using it. b) So we can see which packages supported PyPy 3.10, and test them with PyPy 3.11. Closes: https://github.com/gentoo/guru/pull/291 Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo@sysrq.in>
47 lines
1.3 KiB
Bash
47 lines
1.3 KiB
Bash
# Copyright 2021-2024 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
DISTUTILS_USE_PEP517=setuptools
|
|
PYTHON_COMPAT=( python3_{11..12} )
|
|
|
|
inherit distutils-r1 optfeature
|
|
|
|
DESCRIPTION="A module for Audio/Acoustic Activity Detection"
|
|
HOMEPAGE="https://github.com/amsehili/auditok/"
|
|
SRC_URI="https://github.com/amsehili/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
|
|
|
|
LICENSE="MIT"
|
|
SLOT="0"
|
|
KEYWORDS="~amd64"
|
|
|
|
BDEPEND="
|
|
test? (
|
|
dev-python/pydub[${PYTHON_USEDEP}]
|
|
dev-python/genty[${PYTHON_USEDEP}]
|
|
dev-python/matplotlib[${PYTHON_USEDEP}]
|
|
)
|
|
"
|
|
|
|
distutils_enable_tests unittest
|
|
|
|
python_prepare_all() {
|
|
distutils-r1_python_prepare_all
|
|
|
|
# these tests appear to be broken
|
|
rm "${S}"/tests/test_plotting.py || die
|
|
}
|
|
|
|
python_test() {
|
|
eunittest tests/
|
|
}
|
|
|
|
pkg_postinst() {
|
|
optfeature "reading audio files in popular audio formats (ogg, mp3, etc.) or extracting audio from a video file" dev-python/pydub
|
|
optfeature "reading audio data from the microphone and playing audio back" dev-python/pyaudio
|
|
optfeature "showing progress bar while playing audio clips" dev-python/tqdm
|
|
optfeature "plotting audio signal and detections" dev-python/matplotlib
|
|
optfeature "matplotlib. Also used for some math operations instead of standard python if available" dev-python/numpy
|
|
}
|