mirror of
https://github.com/gentoo-mirror/guru.git
synced 2026-10-12 17:51:11 -04:00
Artemis Everfree
a82de70dbb
Use ${PN} instead of ${P} to share adpcm source between furnace versions. The
adpcm code is from a separate repo, and has its commit hash in the distfile
destination string as the version identifier.
Additionally, unindent the source lines. This is just to (barely) make pkgcheck
not complain about the lines being too long.
Signed-off-by: Artemis Everfree <artemis@artemis.sh>
70 lines
1.8 KiB
Bash
70 lines
1.8 KiB
Bash
# Copyright 1999-2026 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
inherit cmake xdg
|
|
|
|
DESCRIPTION="a multi-system chiptune tracker compatible with DefleMask modules"
|
|
HOMEPAGE="https://github.com/tildearrow/furnace"
|
|
|
|
# when performing updates, check whether the project has switched to a new
|
|
# version of adpcm. adpcm doesn't seem to update frequently.
|
|
SRC_URI="
|
|
https://github.com/tildearrow/furnace/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz
|
|
https://github.com/superctr/adpcm/archive/ef7a217154badc3b99978ac481b268c8aab67bd8.tar.gz -> ${PN}-adpcm-ef7a217.tar.gz
|
|
"
|
|
PATCHES=(
|
|
# Fixed on master branch upstream, remove for future versions
|
|
"${FILESDIR}/0.6.8.3-ymf278h-include-stdint.patch"
|
|
)
|
|
LICENSE="GPL-2+"
|
|
SLOT="0"
|
|
KEYWORDS="~amd64 ~arm64"
|
|
IUSE="jack"
|
|
|
|
RDEPEND="
|
|
dev-libs/libfmt:=
|
|
media-libs/alsa-lib
|
|
media-libs/freetype
|
|
media-libs/libglvnd
|
|
media-libs/libsdl2
|
|
media-libs/libsndfile
|
|
media-libs/portaudio
|
|
media-libs/rtmidi
|
|
sci-libs/fftw
|
|
virtual/zlib:=
|
|
x11-themes/hicolor-icon-theme
|
|
jack? ( virtual/jack )
|
|
"
|
|
DEPEND="${RDEPEND}"
|
|
|
|
src_prepare() {
|
|
# adpcm is a git submodule in-tree, and thus not included in the
|
|
# github-generated source bundle. We move it in here.
|
|
rmdir -v "${S}/extern/adpcm" || die "couldn't remove existing adpcm stub directory"
|
|
mv -v "${WORKDIR}/adpcm-"* "${S}/extern/adpcm" || die "failed to move adpcm directory into place"
|
|
|
|
cmake_src_prepare
|
|
}
|
|
|
|
src_configure() {
|
|
local mycmakeargs=(
|
|
-DBUILD_GUI=ON
|
|
-DSHOW_OPEN_ASSETS_MENU_ENTRY=ON
|
|
-DSYSTEM_FFTW=ON
|
|
-DSYSTEM_FMT=ON
|
|
-DSYSTEM_LIBSNDFILE=ON
|
|
-DSYSTEM_PORTAUDIO=ON
|
|
-DSYSTEM_RTMIDI=ON
|
|
-DSYSTEM_SDL2=ON
|
|
-DSYSTEM_ZLIB=ON
|
|
-DWITH_DEMOS=ON
|
|
-DWITH_INSTRUMENTS=ON
|
|
-DWITH_WAVETABLES=ON
|
|
-DWITH_JACK="$(usex jack ON OFF)"
|
|
)
|
|
|
|
cmake_src_configure
|
|
}
|