mirror of
https://github.com/gentoo-mirror/guru.git
synced 2026-04-07 03:10:15 -04:00
708e906cc2
install the unit file for systemd unconditionally use xdg eclass for the desktop file Signed-off-by: Nicolas PARLANT <nicolas.parlant@parhuet.fr>
58 lines
1.1 KiB
Bash
58 lines
1.1 KiB
Bash
# Copyright 2022-2025 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
inherit meson systemd xdg
|
|
|
|
DESCRIPTION="Keyboard driven and lightweight Wayland notification daemon."
|
|
HOMEPAGE="https://codeberg.org/dnkl/fnott"
|
|
|
|
if [[ "${PV}" == "9999" ]]; then
|
|
inherit git-r3
|
|
EGIT_REPO_URI="https://codeberg.org/dnkl/fnott.git"
|
|
else
|
|
SRC_URI="https://codeberg.org/dnkl/fnott/archive/${PV}.tar.gz -> ${P}.tar.gz"
|
|
S="${WORKDIR}/${PN}"
|
|
KEYWORDS="~amd64"
|
|
fi
|
|
|
|
LICENSE="MIT ZLIB"
|
|
SLOT="0"
|
|
|
|
RDEPEND="
|
|
dev-libs/wayland
|
|
media-libs/fcft
|
|
media-libs/fontconfig
|
|
media-libs/freetype
|
|
media-libs/libpng:=
|
|
media-libs/nanosvg
|
|
sys-apps/dbus
|
|
x11-libs/pixman
|
|
"
|
|
DEPEND="
|
|
${RDEPEND}
|
|
dev-libs/tllist
|
|
>=dev-libs/wayland-protocols-1.32
|
|
"
|
|
BDEPEND="
|
|
dev-util/wayland-scanner
|
|
app-text/scdoc
|
|
"
|
|
|
|
src_configure() {
|
|
local emesonargs=(
|
|
# always install unit
|
|
-Dsystemd-units-dir="$(systemd_get_userunitdir)"
|
|
-Dsystem-nanosvg=enabled
|
|
)
|
|
meson_src_configure
|
|
}
|
|
|
|
src_install() {
|
|
local DOCS=( CHANGELOG.md README.md )
|
|
meson_src_install
|
|
|
|
rm -r "${ED}"/usr/share/doc/"${PN}" || die
|
|
}
|