# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

inherit autotools findlib

DESCRIPTION="Platform for deductive program verification"
HOMEPAGE="http://why3.lri.fr/"
SRC_URI="https://gforge.inria.fr/frs/download.php/file/38425/${P}.tar.gz"

LICENSE="LGPL-2"
SLOT="0"
KEYWORDS="~amd64"
IUSE="coq doc emacs gtk +ocamlopt re sexp +zarith zip"

DEPEND=">=dev-lang/ocaml-4.05.0[ocamlopt?]
		>=dev-ml/menhir-20151112
		dev-ml/num
		coq? ( >=sci-mathematics/coq-8.6 )
		doc? (
			dev-python/sphinx
			dev-python/sphinxcontrib-bibtex
			|| ( dev-texlive/texlive-latex dev-tex/latexmk dev-tex/rubber )
		)
		emacs? ( app-editors/emacs:* )
		gtk? ( dev-ml/lablgtk:*[sourceview,ocamlopt?] )
		re? ( dev-ml/re dev-ml/seq )
		sexp? (
			dev-ml/ppx_deriving[ocamlopt?]
			dev-ml/ppx_sexp_conv[ocamlopt?]
			dev-ml/sexplib[ocamlopt?]
		)
		zarith? ( dev-ml/zarith )
		zip? ( dev-ml/camlzip )"
RDEPEND="${DEPEND}"

DOCS=( CHANGES.md README.md )

src_prepare() {
	mv configure.in configure.ac || die
	sed -i 's/configure\.in/configure.ac/g' Makefile.in || die
	sed -e '/^lib\/why3[a-z]*\$(EXE):/{n;s/-Wall/$(CFLAGS) $(LDFLAGS)/}' \
		-e '/^%.o: %.c/{n;s/\$(CC).*-o/$(CC) $(CFLAGS) -o/}' \
		-i Makefile.in || die
	eautoreconf
	eapply_user
}

src_configure() {
	econf \
		--disable-hypothesis-selection \
		--disable-pvs-libs \
		--disable-isabelle-libs \
		--disable-frama-c \
		--disable-infer \
		--disable-web-ide \
		$(use_enable coq coq-libs) \
		$(use_enable doc) \
		$(use_enable emacs emacs-compilation) \
		$(use_enable gtk ide) \
		$(use_enable ocamlopt native-code) \
		$(use_enable re) \
		$(use_enable sexp pp-sexp) \
		$(use_enable zarith) \
		$(use_enable zip)
}

src_compile() {
	emake
	emake plugins
	use doc && emake doc
}

src_install(){
	findlib_src_preinst
	emake install install-lib DESTDIR="${ED}" || die "make failed"

	einstalldocs
	docompress -x /usr/share/doc/${PF}/examples
	dodoc -r examples
	if use doc; then
		dodoc doc/latex/manual.pdf
		dodoc -r doc/html
	fi
}