dev-python/celery: add 5.3.0_beta1, drop 5.2.6

Closes: https://bugs.gentoo.org/859769
Closes: https://bugs.gentoo.org/841970
Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo@sysrq.in>

dev-python/celery/celery-5.3.0_beta1.ebuild

@@ -0,0 +1,109 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} )
+inherit bash-completion-r1 distutils-r1 optfeature
+
+MY_PV="${PV/_beta/b}"
+DESCRIPTION="Asynchronous task queue/job queue based on distributed message passing"
+HOMEPAGE="
+	https://docs.celeryproject.org/en/stable/index.html
+	https://pypi.org/project/celery/
+	https://github.com/celery/celery
+"
+SRC_URI="https://github.com/celery/celery/archive/v${MY_PV}.tar.gz -> ${P}.gh.tar.gz"
+S="${WORKDIR}/${PN}-${MY_PV}"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="examples"
+
+RDEPEND="
+	>=dev-python/billiard-3.6.4.0[${PYTHON_USEDEP}]
+	<dev-python/billiard-5.0.0[${PYTHON_USEDEP}]
+	dev-python/click[${PYTHON_USEDEP}]
+	dev-python/click-didyoumean[${PYTHON_USEDEP}]
+	dev-python/click-plugins[${PYTHON_USEDEP}]
+	dev-python/click-repl[${PYTHON_USEDEP}]
+	>=dev-python/kombu-5.3.0_beta1[${PYTHON_USEDEP}]
+	<dev-python/kombu-6.0.0[${PYTHON_USEDEP}]
+	dev-python/pytz[${PYTHON_USEDEP}]
+	dev-python/vine[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		$(python_gen_impl_dep 'ncurses(+)')
+		>=dev-python/boto3-1.9.178[${PYTHON_USEDEP}]
+		dev-python/elasticsearch-py[${PYTHON_USEDEP}]
+		>=dev-python/moto-1.3.7[${PYTHON_USEDEP}]
+		dev-python/msgpack[${PYTHON_USEDEP}]
+		dev-python/pylibmc[${PYTHON_USEDEP}]
+		dev-python/pymongo[${PYTHON_USEDEP}]
+		dev-python/pytest-celery[${PYTHON_USEDEP}]
+		dev-python/pytest-click[${PYTHON_USEDEP}]
+		dev-python/pytest-subtests[${PYTHON_USEDEP}]
+		>=dev-python/pytest-timeout-1.4.2[${PYTHON_USEDEP}]
+		>=dev-python/pyyaml-3.10[${PYTHON_USEDEP}]
+		dev-python/redis-py[${PYTHON_USEDEP}]
+		dev-python/sphinx-testing[${PYTHON_USEDEP}]
+		dev-python/tblib[${PYTHON_USEDEP}]
+	)
+	doc? (
+		dev-python/docutils[${PYTHON_USEDEP}]
+		>=dev-python/sphinx_celery-2.0.0[${PYTHON_USEDEP}]
+		>=dev-python/sphinx-click-2.5.0[${PYTHON_USEDEP}]
+		dev-python/jinja[${PYTHON_USEDEP}]
+		dev-python/sqlalchemy[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_DESELECT=(
+	t/unit/tasks/test_result.py::test_EagerResult::test_wait_raises
+	t/unit/tasks/test_tasks.py::test_task_retries
+	t/unit/tasks/test_tasks.py::test_apply_task::test_apply
+	t/unit/utils/test_collections.py::test_ExceptionInfo::test_exception_info
+	t/unit/worker/test_request.py::test_trace_task::test_execute_jail_failure
+	t/unit/worker/test_request.py::test_Request
+	t/unit/worker/test_request.py::test_create_request_class::test_on_success__SystemExit
+)
+
+distutils_enable_tests pytest
+
+distutils_enable_sphinx docs --no-autodoc
+
+python_install_all() {
+	# Main celeryd init.d and conf.d
+	newinitd "${FILESDIR}/celery.initd-r2" celery
+	newconfd "${FILESDIR}/celery.confd-r2" celery
+
+	if use examples; then
+		docinto examples
+		dodoc -r examples/.
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+
+	newbashcomp extra/bash-completion/celery.bash "${PN}"
+
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature "msgpack support" dev-python/msgpack
+	#optfeature "rabbitmq support" dev-python/librabbitmq
+	#optfeature "slmq support" dev-python/softlayer_messaging
+	#optfeature "couchbase support" dev-python/couchbase
+	optfeature "redis support" dev-python/redis-py
+	optfeature "gevent support" dev-python/gevent
+	optfeature "auth support" dev-python/pyopenssl
+	optfeature "pyro support" dev-python/Pyro4
+	optfeature "yaml support" dev-python/pyyaml
+	optfeature "memcache support" dev-python/pylibmc
+	optfeature "mongodb support" dev-python/pymongo
+	optfeature "sqlalchemy support" dev-python/sqlalchemy
+	optfeature "sqs support" dev-python/boto
+	#optfeature "cassandra support" dev-python/cassandra-driver
+}