From ff0fec1c7e71afc5a9c9067b4fc9376618c8092e Mon Sep 17 00:00:00 2001
From: Christopher Fore <csfore@posteo.net>
Date: Sun, 28 Apr 2024 20:20:24 -0400
Subject: [PATCH] sys-apps/ugrep: new package, add 5.1.4

- Tests pass

Signed-off-by: Christopher Fore <csfore@posteo.net>
---
 sys-apps/ugrep/Manifest           |  1 +
 sys-apps/ugrep/metadata.xml       | 17 ++++++++
 sys-apps/ugrep/ugrep-5.1.4.ebuild | 66 +++++++++++++++++++++++++++++++
 3 files changed, 84 insertions(+)
 create mode 100644 sys-apps/ugrep/Manifest
 create mode 100644 sys-apps/ugrep/metadata.xml
 create mode 100644 sys-apps/ugrep/ugrep-5.1.4.ebuild

diff --git a/sys-apps/ugrep/Manifest b/sys-apps/ugrep/Manifest
new file mode 100644
index 0000000000..be28280c3f
--- /dev/null
+++ b/sys-apps/ugrep/Manifest
@@ -0,0 +1 @@
+DIST ugrep-5.1.4.tar.gz 6280906 BLAKE2B 3f6e1a20ec9a5a012d3152562d1792a6c4c49dd0874976128ea408e39269ac6df60f6879e631b8471594c2ed840c46b68de0ce5b0e6f5197b665783e39bbde39 SHA512 d746c77a22a98c2719cc7b443351a3d27f0f2712a2be483596965cc2b6127f28b9e564ca32db1fea950a6315053c89440912d4b7311073bd97d7702f02521378
diff --git a/sys-apps/ugrep/metadata.xml b/sys-apps/ugrep/metadata.xml
new file mode 100644
index 0000000000..fc2bf4ae17
--- /dev/null
+++ b/sys-apps/ugrep/metadata.xml
@@ -0,0 +1,17 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="person">
+    <email>csfore@posteo.net</email>
+    <name>Christopher Fore</name>
+  </maintainer>
+  <upstream>
+    <remote-id type="github">Genivia/ugrep</remote-id>
+  </upstream>
+  <use>
+    <flag name="7zip">Adds support for 7zip packages.</flag>
+    <flag name="boost">Uses <pkg>dev-libs/boost</pkg> for regular expression parsing.</flag>
+    <flag name="bzip3">Adds support for bzip3 packages using <pkg>app-arch/bzip3</pkg>.</flag>
+    <flag name="pcre2">Uses <pkg>dev-libs/libpcre2</pkg> for regular expression parsing.</flag>
+  </use>
+</pkgmetadata>
diff --git a/sys-apps/ugrep/ugrep-5.1.4.ebuild b/sys-apps/ugrep/ugrep-5.1.4.ebuild
new file mode 100644
index 0000000000..72e7599f12
--- /dev/null
+++ b/sys-apps/ugrep/ugrep-5.1.4.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit shell-completion
+
+DESCRIPTION="A fast, drop-in replacement for GNU grep"
+HOMEPAGE="https://ugrep.com/"
+SRC_URI="https://github.com/Genivia/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+IUSE="7zip brotli boost bzip3 cpu_flags_arm_neon cpu_flags_x86_avx2 cpu_flags_x86_sse2 +lzma lz4 +mmap +pcre2 +zlib zstd"
+
+COMMON_DEPEND="
+	brotli? ( app-arch/brotli )
+	boost? ( dev-libs/boost )
+	bzip3? ( app-arch/bzip3 )
+	lz4? ( app-arch/lz4 )
+	lzma? ( app-arch/xz-utils )
+	pcre2? ( dev-libs/libpcre2 )
+	zlib? ( sys-libs/zlib )
+	zstd? ( app-arch/zstd )
+"
+
+RDEPEND="${COMMON_DEPEND}"
+
+DEPEND="
+	${COMMON_DEPEND}
+	virtual/pkgconfig"
+
+src_configure() {
+	local myeconfargs=(
+		$(usev !cpu_flags_arm_neon '--disable-neon')
+		$(usev !cpu_flags_x86_avx2 '--disable-avx2')
+		$(usev !cpu_flags_x86_sse2 '--disable-sse2')
+
+		$(use_enable 7zip)
+		$(use_enable mmap)
+
+		$(use_with brotli)
+		$(use_with bzip3)
+		$(use_with pcre2)
+		$(use_with lzma)
+		$(use_with lz4)
+		$(use_with zlib)
+		$(use_with zstd)
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+	dobashcomp "${S}"/completions/bash/*
+	dofishcomp "${S}"/completions/fish/*
+	dozshcomp "${S}"/completions/zsh/_*
+}
+
+src_test() {
+	# emake check is run first by default in Portage but
+	# that doesn't actually run the tests, emake test does
+	emake test
+}