games-util/minigalaxy: add 1.2.6, enable py3.12

Closes: https://bugs.gentoo.org/897622
Bug: https://bugs.gentoo.org/921890
Bug: https://bugs.gentoo.org/921916
Bug: https://bugs.gentoo.org/927563
Signed-off-by: Julien Roy <julien@jroy.ca>

games-util/minigalaxy/Manifest

@@ -1 +1 @@
-DIST minigalaxy-1.1.0.tar.gz 417215 BLAKE2B 639ce13d25e53d5e81885026268b6ecc372288a81edd8c6e7b36d38c17b158f8953d49a33af92d541aec94e0c8651927002f3adca44c6a9caa2b61b0d6e3fd68 SHA512 5d16120f12398376770a2d2176a127201f1640b83bd8efb576e31eddad5e828bf45f7de7a6394408ef76aafedc126f2f3987920ff2863bbe4668096fa4bf6707
+DIST minigalaxy-1.2.6.tar.gz 457267 BLAKE2B 005150b631643b20ef0a8a2e7b0f1ee74cc4a82d3d42e5836457016451c2446a658ddd017c68f26960b5f8e56fea6edef62df442192ea1dd8d0f811131504ac8 SHA512 99e14c92394cc32fbfcc88fa59c9a9ce2a0f17000edf0c86be0906a3a66104129666e682c3f47fcf2001f93bcee18c1f3d07472eac9c660e978c73cffe3a0943

games-util/minigalaxy/minigalaxy-1.1.0.ebuild

@@ -1,86 +0,0 @@
-# Copyright 2020-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-PYTHON_COMPAT=( python3_10 )
-DISTUTILS_SINGLE_IMPL=1
-
-inherit distutils-r1 optfeature xdg
-
-DESCRIPTION="A simple GOG client for Linux"
-HOMEPAGE="https://github.com/sharkwouter/minigalaxy"
-SRC_URI="https://github.com/sharkwouter/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
-
-LICENSE="GPL-3+"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-
-RDEPEND="
-	$(python_gen_cond_dep '
-		>=dev-python/requests-2.0.0[${PYTHON_USEDEP}]
-		dev-python/pygobject:3[${PYTHON_USEDEP}]
-	')
-	>=net-libs/webkit-gtk-2.6
-	>=x11-libs/gtk+-3
-"
-BDEPEND="test? (
-	$(python_gen_cond_dep '
-		dev-python/simplejson[${PYTHON_USEDEP}]')
-)"
-
-distutils_enable_tests unittest
-
-python_prepare_all() {
-	# AttributeError: module 'minigalaxy.ui' has no attribute 'window'
-	rm tests/test_ui_window.py || die
-
-	# TypeError: issubclass() arg 2 must be a class or tuple of classes
-	rm tests/test_ui_library.py || die
-
-	# fails
-	sed "s/test_create_config/_\0/" -i tests/test_config.py || die
-
-	# require network
-	test_api_net=(
-		test1_get_library
-		test_get_download_file_md5
-		test1_can_connect
-		test2_get_download_info
-	)
-	for fn in "${test_api_net[@]}"; do
-		sed "s/def ${fn}/def _${fn}/" -i tests/test_api.py || die
-	done
-
-	# fail
-	test_installer_fail=(
-		test_remove_installer_from_keep
-		test_remove_installer_keep
-		test_remove_installer_same_content
-	)
-	for fn in "${test_installer_fail[@]}"; do
-		sed "s/def ${fn}/def _${fn}/" -i tests/test_installer.py || die
-	done
-
-	distutils-r1_python_prepare_all
-}
-
-python_test() {
-	eval unset ${!LC_*} LANG
-
-	cp minigalaxy/paths.py minigalaxy/paths.py.bak || die
-	sed "s:\(LAUNCH_DIR =\) .*:\1 \"${BUILD_DIR}/test/usr/bin\":" \
-		-i minigalaxy/paths.py || die
-
-	distutils_install_for_testing
-	distutils-r1_python_test
-
-	mv -f minigalaxy/paths.py.bak minigalaxy/paths.py || die
-}
-
-pkg_postinst() {
-	xdg_pkg_postinst
-
-	optfeature "running games with system dosbox" games-emulation/dosbox
-	optfeature "running games with system scummvm" games-engines/scummvm
-}

games-util/minigalaxy/minigalaxy-1.2.6.ebuild

@@ -0,0 +1,44 @@
+# Copyright 2020-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+# Fails to compile with PEP517
+# DISTUTILS_USE_PEP517=setuptools
+DISTUTILS_SINGLE_IMPL=1
+
+inherit distutils-r1 optfeature xdg
+
+DESCRIPTION="A simple GOG client for Linux"
+HOMEPAGE="https://github.com/sharkwouter/minigalaxy"
+SRC_URI="https://github.com/sharkwouter/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	$(python_gen_cond_dep '
+		>=dev-python/requests-2.0.0[${PYTHON_USEDEP}]
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+	')
+	>=net-libs/webkit-gtk-2.6:4
+	>=x11-libs/gtk+-3
+"
+BDEPEND="
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/simplejson[${PYTHON_USEDEP}]
+		')
+	)
+"
+
+distutils_enable_tests unittest
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	optfeature "running games with system dosbox" games-emulation/dosbox
+	optfeature "running games with system scummvm" games-engines/scummvm
+}