gnome-extra/extension-manager: Add 0.3.0

Signed-off-by: Yuan Liao <liaoyuan@gmail.com>

gnome-extra/extension-manager/Manifest

@@ -1 +1,2 @@
 DIST extension-manager-0.2.3.tar.gz 1384925 BLAKE2B 3bd98f67f419c646a4a7b9d1dee656de305eff5e35124f3765d5d9c82aff7d9e7bbeea912f24c0766c95e0c497b070831ee9922747f200bbcd57470a6adcec7e SHA512 9bb078f3d00cdfe1e84a757f7cce32f5a33333fdf4f60f3952523ac48779becab9c00da78974551f224c194806217eddf3116a29eb33f1e9982ff8caa5e06218
+DIST extension-manager-0.3.0.tar.gz 1431028 BLAKE2B 059d46118b57f204b1258a5d9c55587407130db3048b87be13294e6f426b5d8515475e6b7622cca3ed5951c3f2ed238d22a09ab4f4d1bf78196618b8fe580f29 SHA512 34642d81be67978ac039a17e0762fa1f44ea41720d066a5aeb7fa1e35f2f6ac25a7924b5daf3073ddf4caa3013e1e70b24c5df4c998920ebe1c8e0a875dbec0c

gnome-extra/extension-manager/extension-manager-0.3.0.ebuild

@@ -0,0 +1,77 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome2-utils meson xdg
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/mjakeman/extension-manager.git"
+else
+	SRC_URI="https://github.com/mjakeman/extension-manager/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64"
+fi
+
+DESCRIPTION="A native tool for browsing and installing GNOME Shell Extensions"
+HOMEPAGE="https://github.com/mjakeman/extension-manager"
+
+LICENSE="GPL-3+"
+SLOT="0"
+
+BDEPEND="
+	dev-libs/glib:2
+	dev-util/blueprint-compiler
+	virtual/pkgconfig
+"
+
+RDEPEND="
+	dev-libs/glib:2
+	dev-libs/json-glib
+	gui-libs/gtk:4[introspection]
+	gui-libs/libadwaita:1[introspection]
+	gui-libs/text-engine
+	net-libs/libsoup:3.0
+"
+
+DEPEND="
+	${RDEPEND}
+"
+
+src_configure() {
+	local emesonargs=()
+	if has live ${PROPERTIES}; then
+		# Produce a development build for live ebuild
+		emesonargs+=( -Ddevelopment=true )
+	fi
+	meson_src_configure
+}
+
+# Tests are skipped because as of version 0.2.3, the tests only validate
+# resource files and do not verify any functionality of the program.  Those
+# validations are either already handled by QA checks or not relevant on
+# Gentoo.  For more information about the rationale, please refer to:
+# https://github.com/gentoo/guru/commit/f896bee213fbb62c70e818c1bf503fee2a41919a#comments
+#
+# If tests are to be executed in the future because the upstream adds
+# functionality tests or for other reasons, and should there be no convenient
+# way to skip the validations, the following variable values need to be set:
+#
+# IUSE="test"
+# # 'Validate appstream file' test case requires Internet connection
+# PROPERTIES="test_network"
+# RESTRICT="test"
+# BDEPEND="test? ( dev-libs/appstream-glib dev-util/desktop-file-utils )"
+src_test() {
+	:
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}