dev-python/pydantic-extra-types: new package, add 2.10.6

Signed-off-by: Alfred Wingate <parona@protonmail.com>
Signed-off-by: Paul Zander <negril.nx+gentoo@gmail.com>

dev-python/pydantic-extra-types/Manifest

@@ -0,0 +1 @@
+DIST pydantic_extra_types-2.10.6.tar.gz 141858 BLAKE2B 23d999682e3c8e76cc27935f4c47da4ddbdbc4cdc3015e86b3b7fb3183f6353ff1faf28b6aa947c55e03b1799f87e3cfa612411bfe4b5b18bfb1ccabed6ba049 SHA512 9e469386e583a1be6ab51fa510cceaef043a40b8c76cbc0d477f7c660bdf779cca1df533c99a76d11b6d84db6735b355ad70526f8dfc03b89ae7844f309c47f7

dev-python/pydantic-extra-types/metadata.xml

@@ -0,0 +1,13 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>parona@protonmail.com</email>
+		<name>Alfred Wingate</name>
+	</maintainer>
+	<stabilize-allarches/>
+	<upstream>
+		<remote-id type="github">pydantic/pydantic-extra-types</remote-id>
+		<remote-id type="pypi">pydantic-extra-types</remote-id>
+	</upstream>
+</pkgmetadata>

dev-python/pydantic-extra-types/pydantic-extra-types-2.10.6.ebuild

@@ -0,0 +1,62 @@
+# Copyright 2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{12..14} )
+
+inherit distutils-r1 optfeature pypi
+
+DESCRIPTION="Extra Pydantic types"
+HOMEPAGE="
+	https://github.com/pydantic/pydantic-extra-types
+	https://pypi.org/project/pydantic-extra-types/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	>=dev-python/pydantic-2.5.2[${PYTHON_USEDEP}]
+	dev-python/typing-extensions[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/phonenumbers[${PYTHON_USEDEP}]
+		dev-python/pycountry[${PYTHON_USEDEP}]
+		dev-python/semver[${PYTHON_USEDEP}]
+		dev-python/pymongo[${PYTHON_USEDEP}]
+		dev-python/pytz[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+EPYTEST_IGNORE=(
+	# Requires unpackaged cron-converter
+	tests/test_cron.py
+	tests/test_json_schema.py
+	# Requires unpackaged pendulum
+	tests/test_pendulum_dt.py
+	# Requires unpackaged python-ulid
+	tests/test_ulid.py
+)
+
+EPYTEST_DESELECT=(
+	# https://github.com/pydantic/pydantic-extra-types/issues/346
+	tests/test_coordinate.py::test_json_schema
+)
+
+pkg_postinst() {
+	optfeature_header "Optional type support"
+	optfeature "PhoneNumber" dev-python/phonenumbers
+	optfeature "language_code" dev-python/pycountry
+	optfeature "semantic_version" dev-python/semver
+	# optfeature "ulid" python-ulid
+	# optfeature "pendulum_dt" pendulum
+	optfeature "mongo_object_id" dev-python/pymongo
+	# optfeature "cron" cron-converter
+}