dev-python/sphinxcontrib-restbuilder: enable py3.11, fix tests

Closes: https://bugs.gentoo.org/862510
Closes: https://bugs.gentoo.org/897576
Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo@sysrq.in>

dev-python/sphinxcontrib-restbuilder/Manifest

@@ -1 +1 @@
-DIST sphinxcontrib-restbuilder-0.3.tar.gz 24926 BLAKE2B 885ec51030ef05c9bf528efc5ee8ac1552692d760854c750342947b599411a1d469aff577938286ef22de0e051450605e646b7b904dd69b513c9016ddbc8345c SHA512 0b94d05a2fed1f2203fea94cd3a525a62530ec1777d28d59f9232241dd6816eedf871d6a6f616f6f9ce2946a90143871be09d8cae75747b224a6032e284963ed
+DIST sphinxcontrib-restbuilder-0.3.gh.tar.gz 24926 BLAKE2B 885ec51030ef05c9bf528efc5ee8ac1552692d760854c750342947b599411a1d469aff577938286ef22de0e051450605e646b7b904dd69b513c9016ddbc8345c SHA512 0b94d05a2fed1f2203fea94cd3a525a62530ec1777d28d59f9232241dd6816eedf871d6a6f616f6f9ce2946a90143871be09d8cae75747b224a6032e284963ed

dev-python/sphinxcontrib-restbuilder/sphinxcontrib-restbuilder-0.3-r1.ebuild

@@ -0,0 +1,39 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..11} pypy3 )
+DISTUTILS_USE_PEP517=setuptools
+inherit distutils-r1
+
+MY_PN=${PN#sphinxcontrib-}
+DESCRIPTION="A Sphinx builder/writer to output reStructuredText (rst) files"
+HOMEPAGE="
+	https://pypi.org/project/sphinxcontrib-restbuilder/
+	https://github.com/sphinx-contrib/restbuilder
+"
+SRC_URI="https://github.com/sphinx-contrib/${MY_PN}/archive/refs/tags/${PV}.tar.gz -> ${P}.gh.tar.gz"
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	dev-python/docutils[${PYTHON_USEDEP}]
+	dev-python/sphinx[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+python_compile() {
+	distutils-r1_python_compile
+	find "${BUILD_DIR}" -name '*.pth' -delete || die
+}
+
+python_test() {
+	rm -rf sphinxcontrib || die
+	distutils_write_namespace sphinxcontrib
+	epytest
+}

dev-python/sphinxcontrib-restbuilder/sphinxcontrib-restbuilder-0.3.ebuild

@@ -1,29 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-PYTHON_COMPAT=( python3_{8..10} pypy3 )
-
-inherit distutils-r1
-
-DESCRIPTION="A Sphinx builder/writer to output reStructuredText (rst) files"
-HOMEPAGE="
-	https://github.com/sphinx-contrib/restbuilder
-	https://pypi.org/project/sphinxcontrib-restbuilder/
-"
-SRC_URI="https://github.com/sphinx-contrib/restbuilder/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
-S="${WORKDIR}/${P/sphinxcontrib-/}"
-
-LICENSE="BSD"
-SLOT="0"
-KEYWORDS="~amd64"
-
-RDEPEND="dev-python/sphinx[${PYTHON_USEDEP}]"
-
-distutils_enable_tests pytest
-
-python_install_all() {
-	distutils-r1_python_install_all
-	find "${ED}" -name '*.pth' -delete || die
-}