From f9ea8bb0aa72c6967d3b72e129df090ea12e99c5 Mon Sep 17 00:00:00 2001
From: Julien Roy <julien@jroy.ca>
Date: Sun, 18 Jun 2023 12:43:24 -0400
Subject: [PATCH] net-im/mautrix-signal: add 0.4.3

Signed-off-by: Julien Roy <julien@jroy.ca>
---
 net-im/mautrix-signal/Manifest                |  1 +
 .../mautrix-signal-0.4.3.ebuild               | 80 +++++++++++++++++++
 2 files changed, 81 insertions(+)
 create mode 100644 net-im/mautrix-signal/mautrix-signal-0.4.3.ebuild

diff --git a/net-im/mautrix-signal/Manifest b/net-im/mautrix-signal/Manifest
index 15c840bcc6..577bd2b7d3 100644
--- a/net-im/mautrix-signal/Manifest
+++ b/net-im/mautrix-signal/Manifest
@@ -1 +1,2 @@
 DIST mautrix-signal-0.4.2.gh.tar.gz 99310 BLAKE2B 31150d71bd7be79e081e31399964df2df3f855ea1c779c4f568419c4f84c007fd8c935095f3b1f57987dfcb786ca166682ff2ba6a75be64ee47bd4a1c5318fdc SHA512 381f4838182834e696697bbc1f159d51bd905f8e9a1c1d18b1ccdd84553d383c3f9c71f20dbef74d7634aae587f9db733fa7b944916d4be7cc02f37db7cdb956
+DIST mautrix-signal-0.4.3.gh.tar.gz 104515 BLAKE2B 706f2028da4c30b1a86135b9c55681244ae2ea9a953bebe3986a94486c3b5cde4f2f569a92168d097ad3246f032f138ba19eeaa777b6bdd4ef9c4c8f3f975021 SHA512 0ecb3a1e5cd7624376392de69edeef96271af6bf75b4ac2ca4efb642a1197cf531e37be766b681d5ae1010002cfd117c34423250f12c3cebfbd84f5338500212
diff --git a/net-im/mautrix-signal/mautrix-signal-0.4.3.ebuild b/net-im/mautrix-signal/mautrix-signal-0.4.3.ebuild
new file mode 100644
index 0000000000..8dc7290700
--- /dev/null
+++ b/net-im/mautrix-signal/mautrix-signal-0.4.3.ebuild
@@ -0,0 +1,80 @@
+# Copyright 2022-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..11} )
+
+inherit distutils-r1 optfeature systemd
+
+DESCRIPTION="A Matrix-Signal Messenger puppeting bridge "
+HOMEPAGE="https://github.com/mautrix/signal/"
+SRC_URI="https://github.com/mautrix/signal/archive/v${PV}.tar.gz -> ${P}.gh.tar.gz"
+S="${WORKDIR}/signal-${PV}"
+
+LICENSE="AGPL-3"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	acct-user/${PN}
+	dev-python/aiohttp[${PYTHON_USEDEP}]
+	dev-python/asyncpg[${PYTHON_USEDEP}]
+	dev-python/attrs[${PYTHON_USEDEP}]
+	dev-python/commonmark[${PYTHON_USEDEP}]
+	dev-python/mautrix[${PYTHON_USEDEP}]
+	dev-python/olm[${PYTHON_USEDEP}]
+	dev-python/phonenumbers[${PYTHON_USEDEP}]
+	dev-python/pillow[${PYTHON_USEDEP}]
+	dev-python/pycryptodome[${PYTHON_USEDEP}]
+	dev-python/python-magic[${PYTHON_USEDEP}]
+	dev-python/qrcode[${PYTHON_USEDEP}]
+	dev-python/ruamel-yaml[${PYTHON_USEDEP}]
+	dev-python/signalstickers-client[${PYTHON_USEDEP}]
+	dev-python/unpaddedbase64[${PYTHON_USEDEP}]
+	dev-python/yarl[${PYTHON_USEDEP}]
+	net-libs/signald
+"
+DEPEND="${RDEPEND}"
+
+src_install() {
+	distutils-r1_src_install
+
+	keepdir /var/log/mautrix
+	fowners root:mautrix /var/log/mautrix
+	fperms 770 /var/log/mautrix
+	sed -i -e "s/\/var\/run\/signald\/signald\.sock/\/tmp\/signald\.sock/" "${ED}/usr/example-config.yaml" || die
+	sed -i -e "s/\.\/${PN}.log/\/var\/log\/mautrix\/${PN}.log/" "${ED}/usr/example-config.yaml" || die
+
+	insinto "/etc/mautrix"
+	newins "${ED}/usr/example-config.yaml" "${PN/-/_}.yaml"
+	rm "${ED}/usr/example-config.yaml" || die
+
+	newinitd "${FILESDIR}/${PN}.initd" "${PN}"
+	systemd_dounit "${FILESDIR}/${PN}.service"
+
+	fowners -R root:mautrix /etc/mautrix
+	fperms -R 770 /etc/mautrix
+}
+
+pkg_postinst() {
+	optfeature "Prometheus statistics" dev-python/prometheus_client
+	optfeature "Sqlite backend" dev-python/aiosqlite
+
+	einfo
+	elog ""
+	elog "Before you can use ${PN}, you must configure it correctly"
+	elog "The configuration file is located at \"/etc/mautrix/${PN/-/_}.yaml\""
+	elog "When done, run the following command: emerge --config ${CATEGORY}/${PN}"
+	elog "Then, you must register the bridge with your homeserver"
+	elog "Refer your homeserver's documentation for instructions"
+	elog "The registration file is located at /var/lib/${PN/-/\/}/registration.yaml"
+	elog "Finally, you may start the ${PN} daemon"
+	einfo
+}
+
+pkg_config() {
+	su - "${PN}" -s /bin/sh -c \
+	   "/usr/bin/python -m ${PN/-/_} -c /etc/mautrix/${PN/-/_}.yaml -g -r /var/lib/${PN/-/\/}/registration.yaml"
+}