dev-cpp/mastodonpp: New package.

C++ wrapper for the Mastodon and Pleroma APIs.

Signed-off-by: Ronny (tastytea) Gutbrod <gentoo@tastytea.de>

dev-cpp/mastodonpp/Manifest

@@ -0,0 +1 @@
+DIST mastodonpp-0.5.7.tar.gz 48181 BLAKE2B cce2b9b61c3cb88a5246888d97b5495979b15e41b1e6d5499d09f00cd24fc94b78a983d634ec28dee0d537642294542235efa261faaa3320ab905f7196b16133 SHA512 83efbd32f7cde6a19546c21d99ed1c8b747ac995b69a5e87876bd0ea0aa9c932d0d255ed2cbe5b0fe4a92aec06d6c75d455f13e9537aade31176ec757916b27a

dev-cpp/mastodonpp/mastodonpp-0.5.7.ebuild

@@ -0,0 +1,59 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake
+[[ "${PV}" == "9999" ]] && inherit git-r3
+
+DESCRIPTION="C++ wrapper for the Mastodon and Pleroma APIs."
+HOMEPAGE="https://schlomp.space/tastytea/mastodonpp"
+if [[ "${PV}" != "9999" ]]; then
+	SRC_URI="https://schlomp.space/tastytea/mastodonpp/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	S="${WORKDIR}/${PN}"
+	KEYWORDS="~amd64"
+else
+	EGIT_REPO_URI="https://schlomp.space/tastytea/mastodonpp.git"
+fi
+
+LICENSE="AGPL-3"
+SLOT="0"
+IUSE="doc examples test"
+
+RDEPEND=">=net-misc/curl-7.56.0[ssl]"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	doc? ( app-doc/doxygen[dot] )
+	test? ( dev-cpp/catch )
+"
+
+RESTRICT="!test? ( test )"
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_EXAMPLES=NO
+		-DWITH_TESTS="$(usex test)"
+		-DWITH_DOC="$(usex doc)"
+	)
+
+	cmake_src_configure
+}
+
+src_test() {
+	BUILD_DIR="${BUILD_DIR}/tests" cmake_src_test
+}
+
+src_install() {
+	if use doc; then
+		HTML_DOCS="${BUILD_DIR}/doc/html/*"
+	fi
+
+	if use examples; then
+		docinto examples
+		for file in examples/*.cpp; do
+			dodoc ${file}
+		done
+	fi
+
+	cmake_src_install
+}

dev-cpp/mastodonpp/mastodonpp-9999.ebuild

@@ -0,0 +1,59 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake
+[[ "${PV}" == "9999" ]] && inherit git-r3
+
+DESCRIPTION="C++ wrapper for the Mastodon and Pleroma APIs."
+HOMEPAGE="https://schlomp.space/tastytea/mastodonpp"
+if [[ "${PV}" != "9999" ]]; then
+	SRC_URI="https://schlomp.space/tastytea/mastodonpp/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	S="${WORKDIR}/${PN}"
+	KEYWORDS="~amd64"
+else
+	EGIT_REPO_URI="https://schlomp.space/tastytea/mastodonpp.git"
+fi
+
+LICENSE="AGPL-3"
+SLOT="0"
+IUSE="doc examples test"
+
+RDEPEND=">=net-misc/curl-7.56.0[ssl]"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	doc? ( app-doc/doxygen[dot] )
+	test? ( dev-cpp/catch )
+"
+
+RESTRICT="!test? ( test )"
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_EXAMPLES=NO
+		-DWITH_TESTS="$(usex test)"
+		-DWITH_DOC="$(usex doc)"
+	)
+
+	cmake_src_configure
+}
+
+src_test() {
+	BUILD_DIR="${BUILD_DIR}/tests" cmake_src_test
+}
+
+src_install() {
+	if use doc; then
+		HTML_DOCS="${BUILD_DIR}/doc/html/*"
+	fi
+
+	if use examples; then
+		docinto examples
+		for file in examples/*.cpp; do
+			dodoc ${file}
+		done
+	fi
+
+	cmake_src_install
+}

dev-cpp/mastodonpp/metadata.xml

@@ -0,0 +1,16 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>gentoo@tastytea.de</email>
+		<name>Ronny (tastytea) Gutbrod</name>
+	</maintainer>
+	<upstream>
+		<maintainer>
+			<name>tastytea</name>
+			<email>tastytea@tastytea.de</email>
+		</maintainer>
+		<doc>https://doc.schlomp.space/mastodonpp/</doc>
+		<bugs-to>https://schlomp.space/tastytea/mastodonpp/issues</bugs-to>
+	</upstream>
+</pkgmetadata>