dev-cpp/xsimd: new package, add 10.0.0

Signed-off-by: Kamal Abdellatif <gentoo.kamal@tgf.pw>

dev-cpp/xsimd/Manifest

@@ -0,0 +1 @@
+DIST xsimd-10.0.0.tar.gz 212082 BLAKE2B 2a3c6dd711f9e7ffd32ce3fd9a6056a56768a0f5b6ff412d2c5cd5f82682cac87ed0a68109a449ab6337f89a4719e9ab25f94060d3f675783ce00c79e3378512 SHA512 bd7a363bbebc9196954c8c87271f14f05ca177569fcf080dac91be06ad2801c43fccbb385afd700b80d58c83d77f26ba199a7105672e4a1e55c517d15dd6e8e3

dev-cpp/xsimd/metadata.xml

@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>gentoo.kamal@tgf.pw</email>
+		<name>Kamal Abdellatif</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="github">xtensor-stack/xsimd</remote-id>
+		<doc>https://xsimd.readthedocs.io/en/latest/</doc>
+	</upstream>
+</pkgmetadata>

dev-cpp/xsimd/xsimd-10.0.0.ebuild

@@ -0,0 +1,57 @@
+# Copyright 2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit cmake python-any-r1
+
+DESCRIPTION="C++ wrappers for SIMD intrinsics"
+HOMEPAGE="https://github.com/xtensor-stack/xsimd"
+SRC_URI="https://codeload.github.com/xtensor-stack/${PN}/tar.gz/refs/tags/${PV} -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+
+IUSE="doc test"
+
+BDEPEND="
+	doc? (
+		app-doc/doxygen
+		$(python_gen_any_dep '
+			dev-python/breathe[${PYTHON_USEDEP}]
+			dev-python/sphinx[${PYTHON_USEDEP}]
+		')
+	)
+	test? ( dev-cpp/doctest )
+"
+
+RESTRICT="!test? ( test )"
+
+python_check_deps() {
+	python_has_version \
+		"dev-python/breathe[${PYTHON_USEDEP}]" \
+		"dev-python/sphinx[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	use doc && python-any-r1_pkg_setup
+}
+
+src_configure() {
+	local mycmakeargs=( -DBUILD_TESTS=$(usex test) )
+
+	cmake_src_configure
+}
+
+src_compile() {
+	use test && cmake_src_compile xtest
+
+	if use doc; then
+		cd "${WORKDIR}/${P}/docs" || die
+		emake html BUILDDIR="${BUILD_DIR}"
+		HTML_DOCS=( "${BUILD_DIR}/html/." )
+	fi
+}