dev-vcs/lazygit: 0.61.1 version bump

Signed-off-by: Sergey Torokhov <torokhov-s-a@yandex.ru>

dev-vcs/lazygit/lazygit-0.61.1.ebuild

@@ -0,0 +1,47 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit go-module
+
+DESCRIPTION="Simple terminal UI for git commands"
+HOMEPAGE="https://github.com/jesseduffield/lazygit"
+if [[ "${PV}" == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/jesseduffield/${PN}.git"
+else
+	KEYWORDS="~amd64"
+	SRC_URI="https://github.com/jesseduffield/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+fi
+
+LICENSE="MIT"
+# dependency licenses:
+LICENSE+=" Apache-2.0 BSD-2 BSD ISC MIT Unlicense "
+SLOT="0"
+BDEPEND=">=dev-lang/go-1.25.0"
+RDEPEND="dev-vcs/git"
+
+DOCS=( {CODE-OF-CONDUCT,CONTRIBUTING,README}.md docs )
+
+src_unpack() {
+	if [[ "${PV}" == 9999 ]];then
+		git-r3_src_unpack
+	else
+		default
+	fi
+}
+
+src_compile() {
+	ego build -o "bin/${PN}" \
+		-ldflags "-X main.version=${PV}"
+}
+
+src_test() {
+	ego test ./... -short
+}
+
+src_install() {
+	dobin "bin/${PN}"
+	einstalldocs
+}