dev-util/yaml-language-server: add 1.14.0

Signed-off-by: tastytea <gentoo@tastytea.de>

dev-util/yaml-language-server/yaml-language-server-1.14.0.ebuild

@@ -0,0 +1,43 @@
+# Copyright 2022-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DESCRIPTION="Language Server for YAML Files"
+HOMEPAGE="https://github.com/redhat-developer/yaml-language-server"
+SRC_URI="
+	mirror://npm/${PN}/-/${P}.tgz
+	https://tastytea.de/files/gentoo/${P}-deps.tar.xz
+"
+S="${WORKDIR}"
+
+# NOTE: to generate the dependency tarball:
+#       npm --cache ./npm-cache install $(portageq envvar DISTDIR)/${P}.tgz
+#       tar -caf ${P}-deps.tar.xz npm-cache
+
+LICENSE="0BSD Apache-2.0 BSD BSD-2 CC0-1.0 ISC MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="net-libs/nodejs"
+BDEPEND="net-libs/nodejs[npm]"
+
+src_unpack() {
+	cd "${T}" || die "Could not cd to temporary directory"
+	unpack ${P}-deps.tar.xz
+}
+
+src_install() {
+	npm \
+		--offline \
+		--verbose \
+		--progress false \
+		--foreground-scripts \
+		--global \
+		--prefix "${ED}"/usr \
+		--cache "${T}"/npm-cache \
+		install "${DISTDIR}"/${P}.tgz || die "npm install failed"
+
+	cd "${ED}"/usr/$(get_libdir)/node_modules/${PN} || die "cd failed"
+	einstalldocs
+}