app-text/komikku: bump 0.35.2

Package-Manager: Portage-3.0.28, Repoman-3.0.3
Signed-off-by: Maciej Barć <xgqt@riseup.net>

app-text/komikku/Manifest

@@ -2,3 +2,4 @@ DIST komikku-0.28.1.tar.gz 1670259 BLAKE2B bcb89f644eca7b6e322442316234e5d39d9db
 DIST komikku-0.29.2.tar.gz 1675938 BLAKE2B b593fa015b0d6b5cf2c2686d60731091a7cf68ba7522712df281cd360bdf61fb46eb33cfecc14301ddc309daccd4607ebd563441bb33cd857ec06f940d4e1956 SHA512 3aa286623cd33a787efdd3fde35a67616ef93a542356b1c17fca82d5700b535055eb609393b54bd7e011f7c5949105ddea9b78eb111cc5f4bf2dddbc604c8bc9
 DIST komikku-0.30.0.tar.gz 1676088 BLAKE2B 998dcf327c902f96594d9025dd91628fc7480cfd5068c67a221693cc24bdf4f13955e5c630695e00b0d1d6b2f14925a7e8236019d8cc99f9fbb1405fcb27b211 SHA512 503d32e20ee54f53882e056623e2bba3992397d1703f5796fa0cabe6792cbb8bb9fa50ac19722200cd37976f3a8780e6afff94e7f751d4f5a19b57574c54d50b
 DIST komikku-0.35.1.tar.gz 3352609 BLAKE2B 4231771bb0f4cfd58fc90a0090deec97ac0ecb4ef1158f334755cbd417ae88911734b6906bf4907662d1ee121f7fbc6b8c8da601119d211ff9be5d34ebac2de8 SHA512 2360ae0797ddc47ac06303668a802ddaa77c7fe6007c08623d789002fa85276884fc929a00b50395c00d4500e3911ff7bf366452f151257d53890de849dd9ff3
+DIST komikku-0.35.2.tar.gz 4335169 BLAKE2B 93254ea42612f7e5daffc176db6bd4bdff97ac0be35a489fdf3d7b655160fee2df9b2a0274838edd0c2ac6609ec42ebcab3b8aa6c90203e2a4d86bf0e37828bb SHA512 c834362f54c4d7ce3cc55ac825a24b7026ea14b991f0c862c983da2f15573492296b6799a394296a5a0247c815dc609505807504534a82d49e96411c266af98d

app-text/komikku/komikku-0.35.2.ebuild

@@ -0,0 +1,75 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+MY_PN="${PN^}"
+MY_P="${MY_PN}-v${PV}"
+
+PYTHON_COMPAT=( python3_{8,9} )
+
+inherit python-single-r1 meson gnome2-utils xdg
+
+DESCRIPTION="An online/offline manga reader for GNOME"
+HOMEPAGE="https://gitlab.com/valos/Komikku"
+SRC_URI="https://gitlab.com/valos/${MY_PN}/-/archive/v${PV}/${MY_P}.tar.gz -> ${P}.tar.gz"
+
+RESTRICT="test"
+KEYWORDS="~amd64"
+LICENSE="GPL-3"
+SLOT="0"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DEPEND="
+	>=gui-libs/libhandy-1.2.0
+	>=x11-libs/gtk+-3.24.10:3
+	$(python_gen_cond_dep '
+		dev-python/beautifulsoup4[${PYTHON_USEDEP}]
+		dev-python/cloudscraper[${PYTHON_USEDEP}]
+		dev-python/dateparser[${PYTHON_USEDEP}]
+		dev-python/keyring[${PYTHON_USEDEP}]
+		dev-python/lxml[${PYTHON_USEDEP}]
+		dev-python/natsort[${PYTHON_USEDEP}]
+		dev-python/pillow[${PYTHON_USEDEP}]
+		dev-python/pure-protobuf[${PYTHON_USEDEP}]
+		dev-python/pygobject[${PYTHON_USEDEP}]
+		dev-python/python-magic[${PYTHON_USEDEP}]
+		dev-python/unidecode[${PYTHON_USEDEP}]
+	')
+"
+RDEPEND="
+	${PYTHON_DEPS}
+	${DEPEND}
+"
+
+S="${WORKDIR}/${MY_P}"
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+}
+
+src_install() {
+	meson_src_install
+	python_optimize
+
+	sed -i "s|#!.*|#!/usr/bin/${EPYTHON}|" "${D}/usr/bin/${PN}"  ||
+		die "Failed to fix ${D}/usr/bin/${PN} interpreter"
+}
+
+pkg_preinst() {
+	gnome2_schemas_savelist
+	xdg_pkg_preinst
+}
+
+pkg_postinst() {
+	gnome2_gconf_install
+	gnome2_schemas_update
+	xdg_pkg_postinst
+}
+
+pkg_postrm() {
+	gnome2_gconf_uninstall
+	gnome2_schemas_update
+	xdg_pkg_postrm
+}