dev-python/pipdeptree: new package, add 2.34.0

Signed-off-by: Oz Tiram <oz.tiram@gmail.com>

dev-python/pipdeptree/Manifest

@@ -0,0 +1,2 @@
+DIST pipdeptree-2.34.0.tar.gz 66683 BLAKE2B 120c87113203782106b9e81775b2421aa10bddcd4137ca3d522dc21ee95380d682f470d98115aab5890fb122a5363c316c9049677f49e2c580a9a4a60f6c2328 SHA512 074d85812694b311cccecd61aa09d2c6784acb5ade912effeceba7876a3a17f4097becd29884ff7108cd6b534e48dcf90967278c311a42d5862e618cae9928ef
+DIST pipdeptree-2.34.0.tar.gz.provenance 9462 BLAKE2B d312bca7aac9d418b19f53d2d84271166b0641d3eb61f7bea40518e4761dea03c01ea6005adc6019f9e0a1c4d0a5639f0f1fc206c814fcb8400a008043b8b832 SHA512 f40f55de3b86961adf8d7721d21c34924c662429e02d996247fb8718bf6a8b476bf29112bbaa8e2fc2a3c10c1e1b6f2984bea881a567ca4ab178b71ca72f4832

dev-python/pipdeptree/metadata.xml

@@ -0,0 +1,17 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person" proxied="yes">
+		<email>oz.tiram@gmail.com</email>
+		<name>Oz Tiram</name>
+	</maintainer>
+	<maintainer type="project" proxied="proxy">
+		<email>proxy-maint@gentoo.org</email>
+		<name>Proxy Maintainers</name>
+	</maintainer>
+	<stabilize-allarches/>
+	<upstream>
+		<remote-id type="github">tox-dev/pipdeptree</remote-id>
+		<remote-id type="pypi">pipdeptree</remote-id>
+	</upstream>
+</pkgmetadata>

dev-python/pipdeptree/pipdeptree-2.34.0.ebuild

@@ -0,0 +1,50 @@
+# Copyright 2022-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYPI_VERIFY_REPO=https://github.com/tox-dev/pipdeptree
+PYTHON_COMPAT=( pypy3_11 python3_{11..14} )
+
+inherit distutils-r1 pypi optfeature
+
+DESCRIPTION="Utility for displaying installed packages in a dependency tree"
+HOMEPAGE="
+	https://github.com/tox-dev/pipdeptree/
+	https://pypi.org/project/pipdeptree/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~riscv"
+
+RDEPEND="
+	>=dev-python/packaging-23.1[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/hatch-vcs[${PYTHON_USEDEP}]
+	test? (
+		dev-python/graphviz[${PYTHON_USEDEP}]
+		>=dev-python/virtualenv-20.31.1[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=( pytest-{mock,subprocess} )
+# tests can fail if other packages are being merged simultaneously
+EPYTEST_RERUNS=5
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# upstream lower bounds are meaningless
+	sed -i -e 's:>=[0-9.]*,\?::' pyproject.toml || die
+}
+
+pkg_postinst() {
+	optfeature \
+		"visualising the dependency graph with --graph-output" \
+		dev-python/graphviz
+}