dev-python/pipdeptree: new package, add 2.34.0

Signed-off-by: Oz Tiram <oz.tiram@gmail.com>

dev-python/pipdeptree/pipdeptree-2.34.0.ebuild

@@ -0,0 +1,50 @@
+# Copyright 2022-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYPI_VERIFY_REPO=https://github.com/tox-dev/pipdeptree
+PYTHON_COMPAT=( pypy3_11 python3_{11..14} )
+
+inherit distutils-r1 pypi optfeature
+
+DESCRIPTION="Utility for displaying installed packages in a dependency tree"
+HOMEPAGE="
+	https://github.com/tox-dev/pipdeptree/
+	https://pypi.org/project/pipdeptree/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~riscv"
+
+RDEPEND="
+	>=dev-python/packaging-23.1[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/hatch-vcs[${PYTHON_USEDEP}]
+	test? (
+		dev-python/graphviz[${PYTHON_USEDEP}]
+		>=dev-python/virtualenv-20.31.1[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=( pytest-{mock,subprocess} )
+# tests can fail if other packages are being merged simultaneously
+EPYTEST_RERUNS=5
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# upstream lower bounds are meaningless
+	sed -i -e 's:>=[0-9.]*,\?::' pyproject.toml || die
+}
+
+pkg_postinst() {
+	optfeature \
+		"visualising the dependency graph with --graph-output" \
+		dev-python/graphviz
+}