diff --git a/net-analyzer/zabbix-agent2-plugin-nvidia-gpu/zabbix-agent2-plugin-nvidia-gpu-7.4.13.ebuild b/net-analyzer/zabbix-agent2-plugin-nvidia-gpu/zabbix-agent2-plugin-nvidia-gpu-7.4.13.ebuild
new file mode 100644
index 0000000000..e4019281bf
--- /dev/null
+++ b/net-analyzer/zabbix-agent2-plugin-nvidia-gpu/zabbix-agent2-plugin-nvidia-gpu-7.4.13.ebuild
@@ -0,0 +1,54 @@
+# Copyright 2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DESCRIPTION="NVIDIA GPU loadable plugin for Zabbix Agent 2"
+HOMEPAGE="https://git.zabbix.com/projects/AP/repos/nvidia-gpu/browse"
+SRC_URI="
+	https://git.zabbix.com/rest/api/latest/projects/AP/repos/nvidia-gpu/archive?at=refs%2Ftags%2F${PV}&format=tgz
+		-> ${P}.tar.gz
+	https://github.com/gentoo-golang-dist/${PN}/releases/download/${PV}/${P}-vendor.tar.xz
+"
+
+inherit go-module
+
+S="${WORKDIR}"
+
+LICENSE="AGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+IUSE="test"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	~net-analyzer/zabbix-${PV}[agent2]
+	x11-drivers/nvidia-drivers
+"
+BDEPEND="
+	>=dev-lang/go-1.25.9
+	x11-drivers/nvidia-drivers
+"
+
+DOCS=( "README.md" )
+
+src_unpack() {
+	mkdir "${P}" || die
+	ln --symbolic "${P}/vendor" "${S}/vendor" || die
+	go-module_src_unpack
+}
+
+src_prepare() {
+	default
+	# See https://bugs.gentoo.org/975428
+	sed --in-place 's/^#cgo linux LDFLAGS: -ldl/& -lnvidia-ml/' pkg/nvml/nvml_linux.go || die
+}
+
+src_install() {
+	exeinto "/usr/libexec/zabbix-agent2-plugin"
+	doexe zabbix-agent2-plugin-nvidia-gpu
+
+	insinto /etc/zabbix/zabbix_agent2.d/plugins.d/
+	doins nvidia.conf
+}