dev-libs/librepo: add 1.20.0

Signed-off-by: Takuya Wakazono <pastalian46@gmail.com>

dev-libs/librepo/Manifest

@@ -1 +1,2 @@
 DIST librepo-1.19.0.tar.gz 841780 BLAKE2B 01689cc356a946c61d2018e892d60436fcb7fed02965bb1c48864f6b1735741039e02d4d2471d7659c9dcf0cece5c3b2fdeba8f0696aa1c560cb837fbd2967a5 SHA512 dd6c0cc69a3fa7324e0753b260a394a0ac5587ca73a6d5d567c63e92ced0d71b35b48db573130cfcce2b6bd582fe486f40ca3299439742f0287778f613195e2d
+DIST librepo-1.20.0.tar.gz 844583 BLAKE2B c202c841c4ca538f50bef6f1c5b96c188fa7235aefc85b38cec7857fa322075762a599f2f2540a3804b33e1230cfcb4fb0b96e299b264ff688f2ef3deab6803b SHA512 994b7c17b57d6ae28c09fc9f3463647bde8bb3ac74ca156df28fadc2ac8d3e49dd8b5f42d90759b4eaab84804489e6740d9ad7fdb011090fb3aa6f19cf603123

dev-libs/librepo/librepo-1.20.0.ebuild

@@ -0,0 +1,70 @@
+# Copyright 2024-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="Repodata downloading library"
+HOMEPAGE="https://github.com/rpm-software-management/librepo"
+SRC_URI="https://github.com/rpm-software-management/librepo/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="doc gpgme test +zchunk"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-libs/glib-2.66:2
+	dev-libs/libxml2
+	dev-libs/openssl:=
+	>=net-misc/curl-7.52.0
+	gpgme? ( app-crypt/gpgme:1= )
+	!gpgme? ( >=app-arch/rpm-4.18.0 )
+	zchunk? ( >=app-arch/zchunk-0.9.11 )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	doc? ( app-text/doxygen )
+	test? ( dev-libs/check )
+"
+
+PATCHES=(
+	# getxattr does not seem to work well under QA box. bug #934951
+	"${FILESDIR}/${PN}-1.18.0-disable-checksum-test.patch"
+)
+
+src_prepare() {
+	cmake_src_prepare
+
+	# respect temp directory during tests, bug #924463
+	sed -i "s|/tmp/|${T}/|" tests/testsys.h || die
+
+	# disable python docs
+	sed -i "/python/d" doc/CMakeLists.txt || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_EXAMPLES=OFF
+		-DENABLE_PYTHON=OFF
+		-DENABLE_SELINUX=OFF
+		-DUSE_GPGME=$(usex gpgme)
+		-DENABLE_DOCS=$(usex doc)
+		-DENABLE_TESTS=$(usex test)
+		-DWITH_ZCHUNK=$(usex zchunk)
+	)
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+	use doc && cmake_src_compile doc-c
+}
+
+src_install() {
+	use doc && HTML_DOCS=( "${BUILD_DIR}"/doc/c/html/. )
+	cmake_src_install
+}