diff --git a/media-sound/yandex-music/Manifest b/media-sound/yandex-music/Manifest
index 81ecf9d824..8ee5a91a64 100644
--- a/media-sound/yandex-music/Manifest
+++ b/media-sound/yandex-music/Manifest
@@ -2,3 +2,4 @@ DIST Yandex_Music_amd64_5.95.0.deb 93787630 BLAKE2B 8ac9f5bcc1d2460404dd638504bb
 DIST Yandex_Music_amd64_5.97.3.deb 93807396 BLAKE2B aff29cd0ea9b39cb72bcdd93143301e068d022e28b79d00d0bb83e45c7542a2408be71da16eb736b4c1ba01501f3e2b2504568704a6d578ee56610c5188b2816 SHA512 4cdb080d3b9944c59dfe011504e20b85c5a72663d96dab04b5cad9ba6d42a59c2480a1778a90c5896a6ad46332ff696ccebe4f6e5957edfadacba76b678531ec
 DIST Yandex_Music_amd64_5.100.1.deb 93815746 BLAKE2B ed559fb79735eadeb64bad02b3acebb4aaef9595cbe843ede116cb15f5e676866ad6d395a16fac848d1df095926feb76d06158726cb72b11e11933c42688c2bd SHA512 c765f4cd9b2319db31addb8ba2b51a862bdf515d775fb7ab5b88535d8581122ac1fb04afa062981b6f349ec97789f91da9ba7354ec0ea6be0ef08aca7afc468c
 DIST Yandex_Music_amd64_5.105.3.deb 94305280 BLAKE2B 56803290f9a2231dc6d632d2fc2981596e8561beebda279ec12c938c4c9ac4ad0d8b3fce2fc65325b014f1a5d9c51b2e07296c1de452ff1c671dc48eaa54f280 SHA512 266717e36b1bca1ba1c6f3bb61e86c2cb9308bcef714dd0311ba6d2e55905bb5fe688e2ff0872ab953952dd46db093d47933807fe27ce5f748bcac9611097bac
+DIST Yandex_Music_amd64_5.110.1.deb 94390200 BLAKE2B 88777762fd0844d26e13dd49a411ea78f0c3993f7595f0e0b9c233ed2624a44c28f23c0538fcd593289d3bfd963c266efdf520a578e3511e76ba743191d447fd SHA512 12037c26ab8fd3f8ea852d35bd2c069ca6ed588eae0194e0b06eed5d02d7546f53e9180ddb94231161d0a1fda6d922db5198685ad465b27b391db497753e7d18
diff --git a/media-sound/yandex-music/yandex-music-5.110.1.ebuild b/media-sound/yandex-music/yandex-music-5.110.1.ebuild
new file mode 100644
index 0000000000..d577743e8b
--- /dev/null
+++ b/media-sound/yandex-music/yandex-music-5.110.1.ebuild
@@ -0,0 +1,129 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+CHROMIUM_LANGS="af am ar bg bn ca cs da de el en-GB en-US es-419 es et fa fi fil fr gu he hi hr hu id it ja kn ko \
+lt lv ml mr ms nb nl pl pt-BR pt-PT ro ru sk sl sr sv sw ta te th tr uk ur vi zh-CN zh-TW"
+inherit chromium-2 pax-utils wrapper unpacker xdg
+
+MY_PN="${PN/-/}"
+
+DESCRIPTION="Yandex Music streaming service"
+HOMEPAGE="https://music.yandex.ru/"
+SRC_URI="
+	amd64? ( https://music-desktop-application.s3.yandex.net/stable/Yandex_Music_amd64_${PV}.deb )
+"
+
+S="${WORKDIR}"
+
+LICENSE="Yandex-EULA"
+SLOT="0"
+KEYWORDS="-* ~amd64"
+
+RESTRICT="bindist mirror strip"
+
+RDEPEND="
+	app-accessibility/at-spi2-core
+	app-arch/bzip2
+	dev-libs/expat
+	dev-libs/fribidi
+	dev-libs/glib:2
+	dev-libs/gmp
+	dev-libs/libffi
+	dev-libs/libpcre2
+	dev-libs/libtasn1
+	dev-libs/libunistring
+	dev-libs/nettle
+	dev-libs/nspr
+	dev-libs/nss
+	dev-libs/wayland
+	media-gfx/graphite2
+	media-libs/alsa-lib
+	media-libs/fontconfig
+	media-libs/freetype
+	media-libs/harfbuzz
+	media-libs/libepoxy
+	media-libs/libjpeg-turbo
+	media-libs/libpng
+	media-libs/mesa
+	net-dns/libidn2
+	net-libs/gnutls
+	net-print/cups
+	sys-apps/dbus
+	sys-apps/systemd-utils
+	sys-apps/util-linux
+	sys-devel/gcc
+	sys-libs/glibc
+	sys-libs/libcap
+	virtual/zlib
+	x11-libs/cairo[X,glib]
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+
+	x11-libs/libX11
+	x11-libs/libXau
+	x11-libs/libXcomposite
+	x11-libs/libXcursor
+	x11-libs/libXdamage
+	x11-libs/libXdmcp
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXi
+	x11-libs/libXrandr
+	x11-libs/libXrender
+	x11-libs/libdrm
+	x11-libs/libxcb
+	x11-libs/libxkbcommon
+	x11-libs/pango[X]
+	x11-libs/pixman
+"
+DEPEND="
+	>=dev-util/patchelf-0.9
+"
+
+QA_PREBUILT="*"
+QA_DESKTOP_FILE="usr/share/applications/yandex-music.*\\.desktop"
+YANDEX_HOME="opt/${PN}"
+
+pkg_setup() {
+	chromium_suid_sandbox_check_kernel_config
+}
+
+src_unpack() {
+	unpack_deb ${A}
+	mv -T "${S}/opt/Яндекс Музыка" "${S}/${YANDEX_HOME}" || die
+	mv -T "${S}/usr/share/doc/${MY_PN}" "${S}/usr/share/doc/${PF}" || die
+}
+
+src_prepare() {
+	default
+	sed -i -e "s|/opt/Яндекс Музыка/${MY_PN}|/opt/bin/${PN}|" -i -e "s/Audio;/AudioVideo;/" \
+		"${S}/usr/share/applications/${MY_PN}.desktop" || die
+
+	sed -i -e "s|/opt/Яндекс Музыка|/${YANDEX_HOME}|" "${S}/${YANDEX_HOME}"/resources/apparmor-profile || die
+
+	gunzip "usr/share/doc/${PF}/changelog.gz" || die "Failed to decompress docs"
+
+	rm "${S}/${YANDEX_HOME}"/resources/app-update.yml || die
+
+	pushd "${YANDEX_HOME}/locales" > /dev/null || die
+	chromium_remove_language_paks
+	popd > /dev/null || die
+
+	patchelf --remove-rpath "${S}/${YANDEX_HOME}/chrome-sandbox" || die "Failed to fix library rpath (chrome-sandbox)"
+	patchelf --remove-rpath "${S}/${YANDEX_HOME}/${MY_PN}" || die "Failed to fix library rpath (yandexmusic)"
+}
+
+src_install() {
+	insinto /opt
+	doins -r opt/*
+
+	insinto /usr
+	doins -r usr/*
+
+	make_wrapper ${PN} "/${YANDEX_HOME}/${MY_PN}" "" "/${YANDEX_HOME}" "/opt/bin/"
+
+	fowners root:root "/${YANDEX_HOME}/${MY_PN}"
+	fperms 4711 "/${YANDEX_HOME}/chrome-sandbox"
+	pax-mark m "${ED}${YANDEX_HOME}/chrome-sandbox"
+	fperms 755 "/${YANDEX_HOME}/${MY_PN}"
+}