media-gfx/identity: new package, add 26.03

Signed-off-by: Pavel Sobolev <contact@paveloom.dev>

media-gfx/identity/Manifest

@@ -0,0 +1,2 @@
+DIST identity-26.03-deps.tar.xz 27044736 BLAKE2B b648a72cb016a4414eb4880ad7031118addea678ca3fd4450749282dae7b8819ecd18d08c71f84cc31d1f43a6902b7e430abd2b8f71c931dd10fdb00093abda9 SHA512 444447ad74129a844493b070381803a3abe9e5b4d551ee22f1358ce564457846c00c9fec255977a3114d9ed895796990a0f6a300cee0d10f4d97d6aceaa9aab4
+DIST identity-26.03.tar.bz2 1647857 BLAKE2B 84b8fd38f1b1d827bc4ac13e324752f5f03db14c566ae7ee81752f388336b10a3c79994cebd55008a4bb8e375c17c8883179eb67fdb4e0c33e3b6d8971d98da9 SHA512 eb5391c84e8acdfe7f1c862bf64373f008e96c1bacbd5f4fb6af5ddc594a030a22e15023dad994855cdd0103083a87290f8853bde081b3a71de3e50b740c8b51

media-gfx/identity/identity-26.03.ebuild

@@ -0,0 +1,60 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+RUST_MIN_VER="1.92"
+
+inherit cargo gnome2-utils meson xdg
+
+DESCRIPTION="Compare images and videos"
+HOMEPAGE="
+	https://apps.gnome.org/Identity/
+	https://gitlab.gnome.org/YaLTeR/identity
+"
+SRC_URI="
+	https://gitlab.gnome.org/YaLTeR/identity/-/archive/v${PV}/identity-v${PV}.tar.bz2 -> ${P}.tar.bz2
+	https://gitlab.com/api/v4/projects/69517529/packages/generic/${PN}/${PV}/${P}-deps.tar.xz
+"
+
+S="${WORKDIR}/identity-v${PV}"
+
+LICENSE="Apache-2.0 Apache-2.0-with-LLVM-exceptions BSD GPL-3+ MIT MPL-2.0 Unicode-3.0"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	dev-libs/glib:2
+	gui-libs/gtk:4
+	gui-libs/libadwaita:1
+	media-libs/dav1d
+	media-libs/glycin:2
+	media-libs/gst-plugins-base:1.0
+	media-libs/gstreamer:1.0
+	media-libs/libwebp
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-libs/appstream
+	dev-libs/glib:2
+	dev-util/blueprint-compiler
+	dev-util/desktop-file-utils
+	dev-util/gtk-update-icon-cache
+	sys-devel/gettext
+"
+
+src_configure() {
+	meson_src_configure
+
+	ln -s "${CARGO_HOME}" "${BUILD_DIR}/cargo-home" || die
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}

media-gfx/identity/metadata.xml

@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="person">
+    <name>Pavel Sobolev</name>
+    <email>contact@paveloom.dev</email>
+  </maintainer>
+  <upstream>
+    <bugs-to>https://gitlab.gnome.org/YaLTeR/identity/-/issues</bugs-to>
+    <remote-id type="gnome-gitlab">YaLTeR/identity</remote-id>
+  </upstream>
+</pkgmetadata>