dev-libs/qschematic: add 3.1.0

Signed-off-by: Huang Rui <vowstar@gmail.com>

dev-libs/qschematic/Manifest

@@ -1 +1,2 @@
 DIST qschematic-3.0.3.tar.gz 1561135 BLAKE2B 6fb071fb647ced3bd1c2ce4340aa045c93c61568489acabed64d35079fb1be499943022e37b0055a5996f99f20f337c7488251a08f09919e479773eda7162946 SHA512 53e05d924f9ce714d4dc1cc7175f3789de67ed36c94e91b9db17ea2b9b6d068a2bd0e4c21ff360ed2208413d2174f45437bdfb929005850c1849f98d2e8faacf
+DIST qschematic-3.1.0.tar.gz 1565127 BLAKE2B 888448d71ff8785499842b021312e7d8df11dafd523503662d92436aadc378deb25269c7075e0a01f5c5039e1880381079429f02a849e049c711499beee14188 SHA512 4b50eeaf8a27a5323c807ccb67b7e46eb8037e4d92be709d6c440944591e71fc9162f67c5fb2b544b805e85d023707f63ba0127f1b8646b29d6e17afe4f36d95

dev-libs/qschematic/qschematic-3.1.0.ebuild

@@ -0,0 +1,55 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+MY_PN="QSchematic"
+
+inherit cmake
+
+DESCRIPTION="Library for creating flowcharts and engineering diagrams"
+HOMEPAGE="https://github.com/simulton/QSchematic"
+
+if [[ "${PV}" == "9999" ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/simulton/QSchematic/${MY_PN}.git"
+else
+	SRC_URI="https://github.com/simulton/${MY_PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc64 ~riscv ~x86"
+	S="${WORKDIR}/${MY_PN}-${PV}"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="examples static-libs test wayland +X"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="
+	examples? ( static-libs )
+	test? ( static-libs )
+"
+RDEPEND="
+	>=dev-qt/qtbase-6.5:6=[gui,wayland?,widgets,X?]
+	>=dev-qt/qtimageformats-6.5:6
+	>=dev-qt/qtsvg-6.5:6
+	>=dev-libs/gpds-1.8.4[static-libs?]
+"
+
+DEPEND="
+	${RDEPEND}
+"
+
+BDEPEND="
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_INSTALL_PREFIX="${EPREFIX}/usr"
+		-DQSCHEMATIC_DEPENDENCY_GPDS_TARGET:STRING="gpds::gpds-shared"
+		-DQSCHEMATIC_DEPENDENCY_GPDS_DOWNLOAD=OFF
+		-DQSCHEMATIC_BUILD_DEMO=$(usex examples)
+		-DQSCHEMATIC_BUILD_STATIC=$(usex static-libs)
+		-DQSCHEMATIC_BUILD_SHARED=ON
+	)
+
+	cmake_src_configure
+}