media-libs/openxr-loader: add 1.1.43

Signed-off-by: Patrick Nicolas <patricknicolas@laposte.net>

media-libs/openxr-loader/Manifest

@@ -1 +1,2 @@
 DIST openxr-loader-1.1.40.tar.gz 620341 BLAKE2B 75e0108c803501e3d34b7e494e08ddeffc64d311bfe28e271d23d1b9a621f86f6e296707a59edddf7ec6d0312c81cfce45a512d1c8d99448543878794298003e SHA512 1012dbb152a1b6343eb39c460d68daae87cff42ffaf15b9c4d7efc8abea77ecff45d593bdedb9767c772890022c45374b04e1167296f01c6507fd987a4c25fc2
+DIST openxr-loader-1.1.43.tar.gz 644835 BLAKE2B 75d27b0e382ccfdd5d0bfaede000d8725fcd26b307199a1859fa8745c9c565d823928dae4e1b893cc27ed4a18136392eaaa0f14f37d5378080aef90ab8b5d737 SHA512 e5bc1fe6a8f568d484be0da65cccc6eec8707f00441c34f16e49b685c0a6bb260ab407a758a579ffb264e175f43317add46d6781f0073891b372333b3769fd9f

media-libs/openxr-loader/openxr-loader-1.1.43.ebuild

@@ -0,0 +1,64 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+MY_PN=OpenXR-SDK
+inherit cmake-multilib
+
+if [[ ${PV} == *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/KhronosGroup/${MY_PN}.git"
+	SLOT="0"
+else
+	SRC_URI="https://github.com/KhronosGroup/${MY_PN}/archive/refs/tags/release-${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64"
+	S="${WORKDIR}/${MY_PN}-release-${PV}"
+	SLOT="0/${PV}"
+fi
+
+DESCRIPTION="OpenXR loader"
+HOMEPAGE="https://github.com/KhronosGroup/OpenXR-SDK"
+
+LICENSE="Apache-2.0"
+
+IUSE="+wayland +X"
+REQUIRED_USE="|| ( wayland X )"
+
+# dev-libs/jsoncpp-1.9.6: https://bugs.gentoo.org/940262
+DEPEND="
+	media-libs/vulkan-loader[${MULTILIB_USEDEP}]
+	media-libs/mesa[${MULTILIB_USEDEP}]
+	dev-libs/jsoncpp:=[${MULTILIB_USEDEP}]
+	!=dev-libs/jsoncpp-1.9.6
+	wayland? (
+		dev-libs/wayland[${MULTILIB_USEDEP}]
+		dev-libs/wayland-protocols
+	)
+	X? (
+		x11-libs/libxcb[${MULTILIB_USEDEP}]
+		x11-libs/xcb-util-keysyms
+		x11-libs/libXrandr[${MULTILIB_USEDEP}]
+		x11-libs/libXxf86vm[${MULTILIB_USEDEP}]
+	)
+"
+RDEPEND="${DEPEND}"
+BDEPEND="wayland? ( dev-util/wayland-scanner )"
+
+src_prepare() {
+	sed -i 's;DESTINATION share/doc/openxr;DESTINATION ${CMAKE_INSTALL_DOCDIR};' CMakeLists.txt || die
+
+	cmake_src_prepare
+}
+
+multilib_src_configure() {
+	local mycmakeargs=(
+		-DBUILD_WITH_SYSTEM_JSONCPP=ON
+		-DBUILD_WITH_XLIB_HEADERS=$(usex X)
+		-DBUILD_WITH_XCB_HEADERS=$(usex X)
+		-DBUILD_WITH_WAYLAND_HEADERS=$(usex wayland)
+		-DPRESENTATION_BACKEND=$(usex X xlib wayland)
+	)
+
+	cmake_src_configure
+}