From e2fe1fc8a856eafd77f4593c7bcd49e93127c1fe Mon Sep 17 00:00:00 2001
From: Florian Albrechtskirchinger <falbrechtskirchinger@gmail.com>
Date: Fri, 27 Mar 2026 18:52:53 +0100
Subject: [PATCH] dev-python/http-snapshot: new package, add 0.1.9

Signed-off-by: Florian Albrechtskirchinger <falbrechtskirchinger@gmail.com>
---
 dev-python/http-snapshot/Manifest             |  1 +
 .../http-snapshot/http-snapshot-0.1.9.ebuild  | 52 +++++++++++++++++++
 dev-python/http-snapshot/metadata.xml         | 12 +++++
 3 files changed, 65 insertions(+)
 create mode 100644 dev-python/http-snapshot/Manifest
 create mode 100644 dev-python/http-snapshot/http-snapshot-0.1.9.ebuild
 create mode 100644 dev-python/http-snapshot/metadata.xml

diff --git a/dev-python/http-snapshot/Manifest b/dev-python/http-snapshot/Manifest
new file mode 100644
index 0000000000..0be7d161c6
--- /dev/null
+++ b/dev-python/http-snapshot/Manifest
@@ -0,0 +1 @@
+DIST http-snapshot-0.1.9.gh.tar.gz 117951 BLAKE2B 2efbcb767dc8d084e2c5c629e196e6aba4cb36a8c8f76836a4053706f0375901153a1bd5db316700bc660dd855efb6b4c9233fb7f27fd4df20083c7a1cc554a9 SHA512 836530661757b20bb2df5da62d89956dd5781f8ca358e1f9974c884fbd751f79e0a5f3c851bbbcb28366995e5300f89b2df21eb19ec7d5a8f0425d588c005cfe
diff --git a/dev-python/http-snapshot/http-snapshot-0.1.9.ebuild b/dev-python/http-snapshot/http-snapshot-0.1.9.ebuild
new file mode 100644
index 0000000000..4d71732f16
--- /dev/null
+++ b/dev-python/http-snapshot/http-snapshot-0.1.9.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{12..14} )
+
+inherit distutils-r1 optfeature
+
+DESCRIPTION="A pytest plugin that snapshots requests made with popular Python HTTP clients"
+HOMEPAGE="
+	https://github.com/karpetrosyan/http-snapshot
+	https://pypi.org/project/http-snapshot/
+"
+SRC_URI="
+	https://github.com/karpetrosyan/http-snapshot/archive/refs/tags/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+
+RDEPEND="
+	>=dev-python/inline-snapshot-0.27.2[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		>=dev-python/httpx-0.28.1[${PYTHON_USEDEP}]
+		>=dev-python/requests-2.32.5[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=( inline-snapshot anyio )
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	cat >> pyproject.toml <<-EOF || die
+		[build-system]
+		requires = ["hatchling"]
+		build-backend = "hatchling.build"
+	EOF
+}
+
+pkg_postinst() {
+	optfeature_header "Install supported HTTP clients:"
+	optfeature "httpx" dev-python/httpx
+	optfeature "requests" dev-python/requests
+}
diff --git a/dev-python/http-snapshot/metadata.xml b/dev-python/http-snapshot/metadata.xml
new file mode 100644
index 0000000000..214e140db4
--- /dev/null
+++ b/dev-python/http-snapshot/metadata.xml
@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>falbrechtskirchinger@gmail.com</email>
+		<name>Florian Albrechtskirchinger</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="pypi">http-snapshot</remote-id>
+		<remote-id type="github">karpetrosyan/http-snapshot</remote-id>
+	</upstream>
+</pkgmetadata>