www-client/helium-bin: add 0.7.10.1

Signed-off-by: Jonas Frei <freijon@pm.me>

www-client/helium-bin/Manifest

@@ -1,2 +1,4 @@
+DIST helium-bin-0.7.10.1-amd64.tar.xz 108848340 BLAKE2B 656120530bd35296710a6e671363bd9f20b24d642111eff654dea89187539aee4b42f75a826c250c7119f93fc0c848e878fb33f493e37ecb68a10f70834a3d77 SHA512 f8827ef4cc4a39c167a6a982ffe2871bbf5373560ef479f0cbcd5d2f8e78ba1be30fa649ee3379545309a53ac5e2ff2c4d33058472d849f868671aea591a4082
+DIST helium-bin-0.7.10.1-arm64.tar.xz 103977528 BLAKE2B 01523d79e348c85ca1c694286117386b0e1464b08bd68289138e111d1d8c985d871dfe1c9e8dd19cfe6ec8d7507e9931374af198748d82f27df3a42b74220c30 SHA512 05c80d9c3dd7de6fc96afbe12164e25c0936004b45ea544227eab6afba4644f91a69e37f8e0255ec02b5a3cdb54ab5b57231d9338dade2124a338092fb62d750
 DIST helium-bin-0.7.7.2-amd64.tar.xz 112461288 BLAKE2B aa4183a378329c87f27db3e9c799213ee5c76858e260f52e55e4d470a2f213c8b3e2eae837349812f6f01b20fc936387ee8ad98d1fe6081a075d6b16128c8d96 SHA512 f169bf6e0544d9ec89a2b8ceeee2f0cb1d7d8c65b54cd52482a4808d6d839da70a2c08f31252b947409008c4b85ba08d2396e21c578511b14a07792523af86d7
 DIST helium-bin-0.7.7.2-arm64.tar.xz 107321024 BLAKE2B 3ae6a990198ee6ca09c723c5baea0a10811085104780bcee3160742ed7a5f408211bd65b4204bff5afbaba6612fb8202cd12ab6394c62d9fc8b5b7c299582105 SHA512 c6d861e9fa3fea13f5659b83089ab0969035bf61c1f5e1bf549d4e882a0abcef199bd5b11a3c7a26a52089ac7a6073eface11240d334ed4a8d5e85ff1fcdaf8f

www-client/helium-bin/helium-bin-0.7.10.1.ebuild

@@ -0,0 +1,113 @@
+# Copyright 2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+CHROMIUM_LANGS="af am ar bg bn ca cs da de el en-GB en-US es-419 es
+	et fa fi fil fr gu he hi hr hu id it ja kn ko lt lv ml mr ms nb nl
+	pl pt-BR pt-PT ro ru sk sl sr sv sw ta te th tr uk ur vi zh-CN zh-TW"
+
+inherit chromium-2 desktop pax-utils xdg
+
+DESCRIPTION="Private, fast, and honest web browser based on Chromium"
+HOMEPAGE="https://helium.computer/"
+
+MY_PN="helium"
+MY_P="${MY_PN}-${PV}"
+
+if [[ ${ARCH} == amd64 ]] ; then
+	ARCH_TXT="x86_64"
+elif [[ ${ARCH} == arm64 ]] ; then
+	ARCH_TXT="${ARCH}"
+fi
+
+SRC_URI="
+amd64? ( https://github.com/imputnet/${MY_PN}-linux/releases/download/${PV}/${MY_P}-x86_64_linux.tar.xz -> ${P}-amd64.tar.xz )
+arm64? ( https://github.com/imputnet/${MY_PN}-linux/releases/download/${PV}/${MY_P}-arm64_linux.tar.xz -> ${P}-arm64.tar.xz )
+"
+
+S=${WORKDIR}
+
+LICENSE="GPL-3 BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+
+IUSE="qt6 selinux"
+
+RESTRICT="bindist mirror strip"
+
+RDEPEND="
+	>=app-accessibility/at-spi2-core-2.46.0:2
+	app-misc/ca-certificates
+	dev-libs/expat
+	dev-libs/glib:2
+	dev-libs/nspr
+	>=dev-libs/nss-3.26
+	media-fonts/liberation-fonts
+	media-libs/alsa-lib
+	media-libs/mesa[gbm(+)]
+	net-misc/curl
+	net-print/cups
+	sys-apps/dbus
+	sys-libs/glibc
+	sys-libs/libcap
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf:2
+	|| (
+		x11-libs/gtk+:3[X]
+		gui-libs/gtk:4[X]
+	)
+	x11-libs/libdrm
+	>=x11-libs/libX11-1.5.0
+	x11-libs/libXcomposite
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXrandr
+	x11-libs/libxcb
+	x11-libs/libxkbcommon
+	x11-libs/libxshmfence
+	x11-libs/pango
+	x11-misc/xdg-utils
+	qt6? ( dev-qt/qtbase:6[gui,widgets] )
+	selinux? ( sec-policy/selinux-chromium )
+"
+
+QA_PREBUILT="*"
+
+pkg_setup() {
+	chromium_suid_sandbox_check_kernel_config
+}
+
+# Skip unpack, we're doing it during install
+src_unpack() {
+	:
+}
+
+src_install() {
+	dodir "opt" || die
+	cd "${ED}/opt/" || die
+
+	# Not possible to unpack to target folder, so: unpack, then mv
+	unpack "${P}-${ARCH}.tar.xz"
+	mv ${MY_P}-${ARCH_TXT}_linux ${MY_PN} || die
+
+	cd "${MY_PN}" || die
+
+	pushd "locales" > /dev/null || die
+	# Remove empty .info files
+	rm *.info || die
+	chromium_remove_language_paks
+	popd > /dev/null || die
+
+	rm "libqt5_shim.so" || die
+	if ! use qt6; then
+		rm "libqt6_shim.so" || die
+	fi
+
+	newicon -s 256 "product_logo_256.png" ${MY_PN}.png
+	domenu "${FILESDIR}/${MY_PN}.desktop"
+	dobin "${FILESDIR}/${MY_PN}"
+
+	pax-mark m "chrome"
+}