dev-python/bump2version: new package, add 1.0.1

Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo@sysrq.in>

dev-python/bump2version/Manifest

@@ -0,0 +1 @@
+DIST bump2version-1.0.1.tar.gz 36236 BLAKE2B 74c2f0ad8c875438b597927f9cd8cdc67494b4ea1aefd7b0770d3494093bbb90d8050ec6c225eb7b0c599124b8b77e18ebdf570798674ee421397fe6700eb613 SHA512 687ad38eabdac57a3daf66714166ebb41aaf8e1a42292c69a1eb56738955413d310fecc7b36a7c39aba2e7ca1bc20ff38b4cc0d40a722304689f03a1b6dd0be8

dev-python/bump2version/bump2version-1.0.1.ebuild

@@ -0,0 +1,42 @@
+# Copyright 2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..11} )
+inherit distutils-r1 pypi
+
+DESCRIPTION="Version-bump your software with a single command!"
+HOMEPAGE="
+	https://pypi.org/project/bump2version/
+	https://github.com/c4urself/bump2version
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+BDEPEND="
+	test? (
+		dev-vcs/git
+		dev-vcs/mercurial
+		dev-python/testfixtures[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_DESELECT=(
+	tests/test_cli.py::test_usage_string
+	"tests/test_cli.py::test_regression_help_in_work_dir[git]"
+	"tests/test_cli.py::test_regression_help_in_work_dir[hg]"
+	tests/test_cli.py::test_defaults_in_usage_with_config
+)
+
+distutils_enable_tests pytest
+
+src_test() {
+	git config --global user.email "you@example.com" || die
+	git config --global user.name "Your Name" || die
+
+	distutils-r1_src_test
+}

dev-python/bump2version/metadata.xml

@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>cyber+gentoo@sysrq.in</email>
+		<name>Anna</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="pypi">bump2version</remote-id>
+		<remote-id type="github">c4urself/bump2version</remote-id>
+	</upstream>
+</pkgmetadata>