From dd0bdca51a0ec46dcbd73e91e47c66806e708345 Mon Sep 17 00:00:00 2001
From: Alessandro Barbieri <lssndrbarbieri@gmail.com>
Date: Sun, 9 May 2021 02:15:09 +0200
Subject: [PATCH] dev-python/hunter: new version

Package-Manager: Portage-3.0.18, Repoman-3.0.3
Signed-off-by: Alessandro Barbieri <lssndrbarbieri@gmail.com>
---
 dev-python/hunter/Manifest                    |  1 +
 ...move-setuptools_scm-upper-constraint.patch | 15 +++++
 dev-python/hunter/hunter-3.3.3.ebuild         | 63 +++++++++++++++++++
 dev-python/hunter/metadata.xml                |  4 +-
 4 files changed, 81 insertions(+), 2 deletions(-)
 create mode 100644 dev-python/hunter/files/remove-setuptools_scm-upper-constraint.patch
 create mode 100644 dev-python/hunter/hunter-3.3.3.ebuild

diff --git a/dev-python/hunter/Manifest b/dev-python/hunter/Manifest
index 4766d81ce4..c07b8acdf6 100644
--- a/dev-python/hunter/Manifest
+++ b/dev-python/hunter/Manifest
@@ -1 +1,2 @@
 DIST hunter-3.3.2.tar.gz 535119 BLAKE2B 25551f04d0b2dafa6875c5c5660d2c57417bdc113960ec2b8d224c88a6b9d08b38bfbbb2deb516e7a36704164318137f5675409850c2eeff2c486a819731c756 SHA512 e3b5e7a3729074cf52a7a209e6f54a1319b3e94ff50abe4e6d8f00f3953720e3c2380de066c2a0a4e56c7a348fdd947425ae19c8907bd420d10ffb271bc07516
+DIST hunter-3.3.3.tar.gz 535662 BLAKE2B f2aa247eec34de982ab56430a0517c483609edc72d3d366a725dabf28ff6621a49411dd41a7ae16846960bb22ec4a7dc1cdb2b528a620e9eac9dc26dabec6213 SHA512 661b0f33653a6175f2172e45386c822552464a06129e2f5c8d4b88f6142a4aecc69bd657dc98ef7ffbb3d93cde537aa3a2e5f68bbced6f03b6514d39cfb99df4
diff --git a/dev-python/hunter/files/remove-setuptools_scm-upper-constraint.patch b/dev-python/hunter/files/remove-setuptools_scm-upper-constraint.patch
new file mode 100644
index 0000000000..5e831b9064
--- /dev/null
+++ b/dev-python/hunter/files/remove-setuptools_scm-upper-constraint.patch
@@ -0,0 +1,15 @@
+--- a/setup.py
++++ b/setup.py
+@@ -163,10 +163,10 @@
+         ':platform_system != "Windows"': ['manhole >= 1.5'],
+     },
+     setup_requires=[
+-        'setuptools_scm>=3.3.1,!=4.0.0,<6.0',
++        'setuptools_scm>=3.3.1',
+         'cython',
+     ] if Cython else [
+-        'setuptools_scm>=3.3.1,!=4.0.0,<6.0',
++        'setuptools_scm>=3.3.1',
+     ],
+     entry_points={
+         'console_scripts': [
diff --git a/dev-python/hunter/hunter-3.3.3.ebuild b/dev-python/hunter/hunter-3.3.3.ebuild
new file mode 100644
index 0000000000..66200e1ea2
--- /dev/null
+++ b/dev-python/hunter/hunter-3.3.3.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7,8} )
+
+DISTUTILS_USE_SETUPTOOLS=rdepend
+
+inherit distutils-r1
+
+DESCRIPTION="Hunter is a flexible code tracing toolkit"
+HOMEPAGE="
+	https://github.com/ionelmc/python-hunter
+	https://pypi.org/project/hunter
+"
+SRC_URI="https://github.com/ionelmc/python-${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/python-${P}"
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="dev-python/colorama[${PYTHON_USEDEP}]"
+DEPEND="
+	${RDEPEND}
+	test? (
+		dev-python/aspectlib[${PYTHON_USEDEP}]
+		dev-python/ipdb[${PYTHON_USEDEP}]
+		dev-python/manhole[${PYTHON_USEDEP}]
+		dev-python/process-tests[${PYTHON_USEDEP}]
+		dev-python/pytest-benchmark[${PYTHON_USEDEP}]
+		dev-python/six[${PYTHON_USEDEP}]
+	)
+"
+BDEPEND="
+	dev-python/cython[${PYTHON_USEDEP}]
+	>=dev-python/setuptools_scm-3.3.1[${PYTHON_USEDEP}]
+"
+
+PATCHES=( "${FILESDIR}/remove-setuptools_scm-upper-constraint.patch" )
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs ">=dev-python/sphinx-py3doc-enhanced-theme-2.3.2"
+
+python_prepare_all() {
+	# all tests in this file fail
+	rm tests/test_remote.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile() {
+	distutils-r1_python_compile
+
+	if use test; then
+		"${EPYTHON}" tests/setup.py build_ext --force --inplace || die
+	fi
+}
+
+python_test() {
+	local -x PYTHONPATH="${S}/tests:${BUILD_DIR}/lib:${PYTHONPATH}"
+	epytest
+}
diff --git a/dev-python/hunter/metadata.xml b/dev-python/hunter/metadata.xml
index 0d170b8b8c..c0ae146367 100644
--- a/dev-python/hunter/metadata.xml
+++ b/dev-python/hunter/metadata.xml
@@ -67,7 +67,7 @@ From the other perspective, you'd be wondering if you could use Hunter to measur
 In other words, filtering events is the main selling point of Hunter - it's fast (cython implementation) and the query API is flexible enough.
   </longdescription>
   <upstream>
-    <remote-id type="github">python-hyper/hyper-h2</remote-id>
-    <remote-id type="pypi">h2</remote-id>
+    <remote-id type="github">ionelmc/python-hunter</remote-id>
+    <remote-id type="pypi">hunter</remote-id>
   </upstream>
 </pkgmetadata>