gui-wm/phoc: add 0.44.1

Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo@sysrq.in>

gui-wm/phoc/Manifest

@@ -4,3 +4,5 @@ DIST phoc-0.43.0.tar.xz 689036 BLAKE2B 4a89bd56ff1fff983d6f99d84165bae0e2a0a6295
 DIST phoc-0.43.0.tar.xz.asc 833 BLAKE2B 6f8aeea6582188b7d57fea8621384b260eb2dd3ffbc9bb6b879f819fb713e420e1fea00013026f07b27983c8725c2e8e8f0774ea9a7a2e454ff5039d3739ca8f SHA512 a64445e050477b9174b2d25a8302812155f9286401fbaad7dc125fec0c70889fd8776c0880c278e7d00799177e666f8144287e1c3939af033598802b9f9fe5c5
 DIST phoc-0.44.0.tar.xz 689792 BLAKE2B 47f4ad8b5fed5527eee460e1130273b22fe4c9d7aa1a0984750036915f2faea2a6eae606a64eda360250fe89491308f3f54a73d764c324bf553706edb8f664d5 SHA512 e7c78dbca7253da86538b2a3809eaf8b185d9d78d8843e8b12b2e435ab529495bc5c77a7cd23bd8b621c0d1f132abdd8a6c9a567586082360e517417fb4f0f94
 DIST phoc-0.44.0.tar.xz.asc 833 BLAKE2B 565eda07b26200d74626e7eee608d8200550c39340adb975f7bd93623486cc5696443c76a89f23d89418bf13f60238fe15200539b87b540cf202a3ab8670ac84 SHA512 9704e505f095e48270c6b011e5318fe3676cfdc9eb2b08dbc705c3c44b68b18b1f62776ffd7287c5fcda3931372578323a4fee3b652c902c245a5d7970f1f484
+DIST phoc-0.44.1.tar.xz 689848 BLAKE2B 49e5782aedba3aba25e1bc2647b89d1e083fcfd2c77828a8816eef538dc1967d5ef1d407a029dcf92c26ef7ee97b9d0c7198bea906f1b5344ac193e6024a9b4b SHA512 99fcd9bc4dc65cb3776d9a1123886c594e5cd303c36037070d7889ebbd9c8a8ace2115bae53c6df6e127e31047da9f2a82508eeb2a6a5b8befe5459f5e4ac232
+DIST phoc-0.44.1.tar.xz.asc 833 BLAKE2B dd462708672966d14fb4517b8bdf6ce70c9b74ef16ef20e0379cdab36daace663197fd019e21ffe30d2ac80bbde38dc260ae9e6b2bd41aedc507ed584ce5b367 SHA512 35145f2ca15f189fda02d4eeee3ab6d28d03903be81ea04a2fafb9c8f7f9573260a76c111304ba354e7172578d67eba1b12dd6be0b7ec34a4bf4f7e7621f7e54

gui-wm/phoc/phoc-0.44.1.ebuild

@@ -0,0 +1,114 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome2-utils meson verify-sig virtualx xdg
+
+DESCRIPTION="Wayland compositor for mobile phones"
+HOMEPAGE="https://gitlab.gnome.org/World/Phosh/phoc"
+SRC_URI="https://sources.phosh.mobi/releases/${PN}/${P}.tar.xz
+	verify-sig? ( https://sources.phosh.mobi/releases/${PN}/${P}.tar.xz.asc )
+"
+
+LICENSE="|| ( GPL-3+ MIT ) GPL-3+ LGPL-2.1+ MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+IUSE="gtk-doc man test"
+RESTRICT="!test? ( test )"
+
+WLROOTS_DEPEND="
+	>=dev-libs/libinput-1.14.0:=
+	>=dev-libs/wayland-1.22.0
+	media-libs/libdisplay-info:=
+	media-libs/libglvnd
+	|| (
+		>=media-libs/mesa-24.1.0_rc1[opengl]
+		<media-libs/mesa-24.1.0_rc1[egl(+),gles2]
+	)
+	sys-apps/hwdata
+	sys-auth/seatd:=
+	x11-base/xwayland
+	x11-libs/cairo
+	>=x11-libs/libdrm-2.4.114
+	x11-libs/libxcb:=
+	x11-libs/libxkbcommon
+	>=x11-libs/pixman-0.42.0
+	x11-libs/xcb-util-errors
+	x11-libs/xcb-util-renderutil
+	x11-libs/xcb-util-wm
+	virtual/libudev
+	amd64? ( >=dev-libs/libliftoff-0.4 )
+"
+COMMON_DEPEND="${WLROOTS_DEPEND}
+	>=dev-libs/glib-2.74:2
+	dev-libs/gmobile
+	dev-libs/libinput:=
+	dev-libs/wayland
+	>=gnome-base/gnome-desktop-3.26:3
+	gnome-base/gsettings-desktop-schemas
+	x11-libs/pixman
+	x11-libs/libxcb:=
+	x11-libs/libxkbcommon
+"
+DEPEND="${COMMON_DEPEND}
+	test? ( x11-wm/mutter )
+"
+RDEPEND="${COMMON_DEPEND}"
+BDEPEND="
+	dev-libs/glib:2
+	dev-libs/wayland-protocols
+	dev-util/wayland-scanner
+	sys-devel/gettext
+	gtk-doc? ( dev-util/gi-docgen )
+	man? ( dev-python/docutils )
+	verify-sig? ( sec-keys/openpgp-keys-phosh )
+"
+
+VERIFY_SIG_OPENPGP_KEY_PATH="/usr/share/openpgp-keys/phosh.asc"
+
+src_prepare() {
+	default
+
+	cd subprojects/wlroots || die
+	eapply "${S}"/subprojects/packagefiles/wlroots
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use gtk-doc gtk_doc)
+		$(meson_use man)
+		$(meson_use test tests)
+		-Ddefault_library=static
+		-Dembed-wlroots=enabled
+		-Dxwayland=enabled
+	)
+	meson_src_configure
+}
+
+src_test() {
+	local -x LC_ALL="C.UTF-8"
+	virtx meson_src_test
+}
+
+src_install() {
+	meson_src_install --skip-subprojects wlroots
+
+	if use gtk-doc; then
+		mkdir -p "${ED}"/usr/share/gtk-doc/html/ || die
+		mv "${ED}"/usr/share/doc/${PN}-${SLOT} "${ED}"/usr/share/gtk-doc/html/ || die
+	fi
+
+	newbin helpers/auto-maximize phoc-auto-maximize
+	newbin helpers/scale-to-fit phoc-scale-to-fit
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}