app-text/komikku: add 1.36.0

Signed-off-by: Takuya Wakazono <pastalian46@gmail.com>

app-text/komikku/Manifest

@@ -1,2 +1,3 @@
 DIST Komikku-v1.21.1.tar.bz2 5170689 BLAKE2B 37801b5f51179d8ba64616a948a6249418ba2ad608aa8efc944d9ee2b9dcb7ae786a2ee6f73696c66b51e20263c856aa338e6711cdf4e25bad7d591c14db23e6 SHA512 28ca35932d5286dde93586e1f8e4a91ce871e278d03b8c86e7efb39a06cd59a5cb482fa5e81bf4804fa419dae3b15e7744fa6a85de1ee3f92985d390b9cde77f
 DIST Komikku-v1.22.0.tar.bz2 5176710 BLAKE2B 902f6c10ef8b9782fb3f1957b2fe00d0e4eb7ca29fa3a03fca04e210e73a0165d5cfb9e272bcfb70cbdf114ee68fd1a6b1f4a86025824bf173394776f515a0c1 SHA512 10565cf1a0df3646d5761e8ee97b7bea2e426e582f7704efb538fb9fae9b5dc7e14be937c559ff17a02142e55af981c5b08b34a95e20153ca2c9c744969de4ea
+DIST komikku-1.36.0.tar.gz 3831735 BLAKE2B 159bae8b1df46741ceed645672d0e0e5c48fe89eee04b03f67031780c9b893d1fd941eb16f887ea59deb1492dc2f250ce9f636c214fb30c058ec4d59c7b56b3c SHA512 41f5b30076905e89ef7ba206747a4c8112486aed962a463963bdeb0211dd5c46e19db66143659dd5e8e521a3d544dcaf06368df4256d8172f70c0ea85bd3c20f

app-text/komikku/komikku-1.36.0.ebuild

@@ -0,0 +1,94 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+PYTHON_REQ_USE="sqlite(+),ssl(+)"
+DISTUTILS_USE_PEP517=no
+DISTUTILS_SINGLE_IMPL=1
+inherit distutils-r1 meson gnome2-utils xdg
+
+DESCRIPTION="Manga reader for GNOME"
+HOMEPAGE="https://apps.gnome.org/Komikku/"
+SRC_URI="https://codeberg.org/valos/Komikku/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${PN}"
+
+KEYWORDS="~amd64"
+LICENSE="GPL-3+"
+SLOT="0"
+IUSE="test"
+
+RESTRICT="test"
+# Depend on a random server that may or may not be accessible at all times.
+#PROPERTIES="test_network"
+
+DEPEND="
+	dev-libs/glib:2
+	dev-libs/gobject-introspection
+	>=gui-libs/gtk-4.12.1:4
+	>=gui-libs/libadwaita-1.4:1[introspection]
+	net-libs/webkit-gtk:6[introspection]
+"
+RDEPEND="
+	${DEPEND}
+	x11-libs/libnotify[introspection]
+	$(python_gen_cond_dep '
+		app-arch/brotli[python,${PYTHON_USEDEP}]
+		dev-python/beautifulsoup4[${PYTHON_USEDEP}]
+		dev-python/colorthief[${PYTHON_USEDEP}]
+		dev-python/cryptography[${PYTHON_USEDEP}]
+		dev-python/dateparser[${PYTHON_USEDEP}]
+		dev-python/emoji[${PYTHON_USEDEP}]
+		dev-python/keyring[${PYTHON_USEDEP}]
+		dev-python/lxml[${PYTHON_USEDEP}]
+		dev-python/natsort[${PYTHON_USEDEP}]
+		dev-python/piexif[${PYTHON_USEDEP}]
+		dev-python/pillow[${PYTHON_USEDEP}]
+		dev-python/pure-protobuf[${PYTHON_USEDEP}]
+		dev-python/pygobject[${PYTHON_USEDEP}]
+		dev-python/python-magic[${PYTHON_USEDEP}]
+		dev-python/rarfile[compressed,${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/unidecode[${PYTHON_USEDEP}]
+	')
+"
+BDEPEND="
+	dev-util/blueprint-compiler
+	sys-devel/gettext
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/pytest-steps[${PYTHON_USEDEP}]
+		')
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# fix broken shebang
+	sed "s|py_installation.full_path()|'${PYTHON}'|" -i bin/meson.build || die
+}
+
+src_test() {
+	emake setup
+	emake develop
+	emake test
+}
+
+src_install() {
+	meson_src_install
+	python_optimize
+}
+
+pkg_postinst() {
+	gnome2_schemas_update
+	xdg_pkg_postinst
+}
+
+pkg_postrm() {
+	gnome2_schemas_update
+	xdg_pkg_postrm
+}

app-text/komikku/metadata.xml

@@ -3,6 +3,6 @@
 <pkgmetadata>
 	<!-- maintainer-needed -->
 	<upstream>
-		<remote-id type="gitlab">valos/Komikku</remote-id>
+		<remote-id type="codeberg">valos/Komikku</remote-id>
 	</upstream>
 </pkgmetadata>