dev-util/find-work: add 0.3.0

Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo@sysrq.in>

dev-util/find-work/Manifest

@@ -1 +1,2 @@
 DIST find_work-0.2.0.tar.gz 11440 BLAKE2B 507da062ca3a30885fedf49831be2454ea2012aabab052599fd3d2740d3a30b602c5b0eb2e7e69699dc5858f279d7dc041481f1fd9c7403b19f18c3953d32d76 SHA512 ad38a464bb682c18e5ae49f15e00041909bc6104ba59efb21a2447b7da84872b2ec191071a60721d50e6eacfeecbbe46d790faffe1e4232a49d8da31bce40e5d
+DIST find_work-0.3.0.tar.gz 16939 BLAKE2B f80bb5436ff70debe3fa1c2c3cec09bb2701e8b60b1a2397de74b1035aa925d935228928a8e6a6eb6b75b218c2a062b2466c963718c89ba5ca4b8457923a3c72 SHA512 e52bcd8636003f1940fd42c3baca22b69654b35f62b9b2ee3345625d4fb1b31a9124c4da3d17e9fec84162eb7b7190553599f7e8a6eda60fb92f946aefaf1c95

dev-util/find-work/find-work-0.3.0.ebuild

@@ -0,0 +1,70 @@
+# Copyright 2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+DISTUTILS_USE_PEP517=hatchling
+inherit distutils-r1 pypi shell-completion
+
+DESCRIPTION="Personal advice utility for Gentoo package maintainers"
+HOMEPAGE="
+	https://find-work.sysrq.in/
+	https://pypi.org/project/find-work/
+"
+
+LICENSE="WTFPL-2"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	<app-portage/gentoopm-2[${PYTHON_USEDEP}]
+	>=dev-python/aiohttp-3[${PYTHON_USEDEP}]
+	<dev-python/aiohttp-4[${PYTHON_USEDEP}]
+	dev-python/click[${PYTHON_USEDEP}]
+	dev-python/click-aliases[${PYTHON_USEDEP}]
+	>=dev-python/pydantic-2[${PYTHON_USEDEP}]
+	<dev-python/pydantic-3[${PYTHON_USEDEP}]
+	dev-python/python-bugzilla[${PYTHON_USEDEP}]
+	>=dev-python/repology-client-0.0.2[${PYTHON_USEDEP}]
+	<dev-python/repology-client-2[${PYTHON_USEDEP}]
+	>=dev-python/requests-2[${PYTHON_USEDEP}]
+	<dev-python/requests-3[${PYTHON_USEDEP}]
+	dev-python/sortedcontainers[${PYTHON_USEDEP}]
+	dev-python/tabulate[${PYTHON_USEDEP}]
+"
+BDEPEND="test? ( dev-python/pytest-recording[${PYTHON_USEDEP}] )"
+
+distutils_enable_tests pytest
+
+distutils_enable_sphinx docs \
+	dev-python/insipid-sphinx-theme \
+	dev-python/sphinx-prompt
+
+src_prepare() {
+	distutils-r1_src_prepare
+	mkdir completions || die
+}
+
+python_compile() {
+	distutils-r1_python_compile
+
+	local -x PATH="${BUILD_DIR}/install${EPREFIX}/usr/bin:${PATH}"
+	local -x PYTHONPATH="${BUILD_DIR}/lib:${PYTHONPATH}"
+	emake completions/find-work.{bash,zsh,fish}
+}
+
+src_install() {
+	distutils-r1_src_install
+
+	local mymakeargs=(
+		DESTDIR="${D}"
+		PREFIX="${EPREFIX}"/usr
+
+		BASHCOMPDIR="$(get_bashcompdir)"
+		ZSHCOMPDIR="$(get_zshcompdir)"
+		FISHCOMPDIR="$(get_fishcompdir)"
+	)
+
+	emake "${mymakeargs[@]}" install-data
+}