From d6b3f93a8812e8ca6d07bd7add5044c07b7258e0 Mon Sep 17 00:00:00 2001
From: "Anna (cybertailor) Vyalkova" <cyber+gentoo@sysrq.in>
Date: Wed, 30 Oct 2024 05:00:48 +0500
Subject: [PATCH] dev-util/bump-my-version: new package, add 0.28.0

Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo@sysrq.in>
---
 dev-util/bump-my-version/Manifest             |  1 +
 .../bump-my-version-0.28.0.ebuild             | 54 +++++++++++++++++++
 dev-util/bump-my-version/metadata.xml         | 17 ++++++
 3 files changed, 72 insertions(+)
 create mode 100644 dev-util/bump-my-version/Manifest
 create mode 100644 dev-util/bump-my-version/bump-my-version-0.28.0.ebuild
 create mode 100644 dev-util/bump-my-version/metadata.xml

diff --git a/dev-util/bump-my-version/Manifest b/dev-util/bump-my-version/Manifest
new file mode 100644
index 0000000000..d6f2e72aaa
--- /dev/null
+++ b/dev-util/bump-my-version/Manifest
@@ -0,0 +1 @@
+DIST bump_my_version-0.28.0.tar.gz 983361 BLAKE2B c77277af977d23b14dd64d0b86789e4f377b2dbb82cd240527f6e3d18d617036138385227be5288c4d0ab58aceece386ea2a9d50f35f0eb6d5b96e972688fa78 SHA512 31a57a0a8de6e18602cc2916021b001b2c1582f82b6d3b9c37851962edbb7b7b6c6a3bbf32c039e6543a81cdbe2a72984a9093323b12d25467e27c5bbee9594c
diff --git a/dev-util/bump-my-version/bump-my-version-0.28.0.ebuild b/dev-util/bump-my-version/bump-my-version-0.28.0.ebuild
new file mode 100644
index 0000000000..22144dcb94
--- /dev/null
+++ b/dev-util/bump-my-version/bump-my-version-0.28.0.ebuild
@@ -0,0 +1,54 @@
+# Copyright 2023-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{11..12} )
+inherit distutils-r1 pypi
+
+DESCRIPTION="Version bump your Python project"
+HOMEPAGE="
+	https://pypi.org/project/bump-my-version/
+	https://callowayproject.github.io/bump-my-version/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	dev-python/click[${PYTHON_USEDEP}]
+	>=dev-python/pydantic-2.0[${PYTHON_USEDEP}]
+	dev-python/pydantic-settings[${PYTHON_USEDEP}]
+	dev-python/questionary[${PYTHON_USEDEP}]
+	dev-python/rich[${PYTHON_USEDEP}]
+	dev-python/rich-click[${PYTHON_USEDEP}]
+	dev-python/tomlkit[${PYTHON_USEDEP}]
+	>=dev-python/wcmatch-8.5.1[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-vcs/git
+		dev-vcs/mercurial
+		dev-python/freezegun[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+	)
+"
+
+DOCS=( {CHANGELOG,CODE_OF_CONDUCT,CONTRIBUTING,README}.md )
+
+distutils_enable_tests pytest
+
+python_test() {
+	epytest -o "addopts="
+}
+
+src_test() {
+	local -x TZ="UTC"
+
+	git config --global user.email "you@example.com" || die
+	git config --global user.name "Your Name" || die
+
+	distutils-r1_src_test
+}
diff --git a/dev-util/bump-my-version/metadata.xml b/dev-util/bump-my-version/metadata.xml
new file mode 100644
index 0000000000..6794711587
--- /dev/null
+++ b/dev-util/bump-my-version/metadata.xml
@@ -0,0 +1,17 @@
+<?xml version='1.0' encoding='UTF-8'?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>cyber+gentoo@sysrq.in</email>
+		<name>Anna</name>
+	</maintainer>
+	<upstream>
+		<maintainer>
+			<name>Corey Oordt</name>
+			<email>coreyoordt@gmail.com</email>
+		</maintainer>
+		<remote-id type="github">callowayproject/bump-my-version</remote-id>
+		<remote-id type="pypi">bump-my-version</remote-id>
+		<doc>https://callowayproject.github.io/bump-my-version/</doc>
+	</upstream>
+</pkgmetadata>