mirrors/guru
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/guru.git synced 2026-07-12 08:33:15 -04:00
Code Issues Packages Projects Releases Wiki Activity

dev-python/python-pkcs11: enable py3.11

Browse Source 
Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo@sysrq.in>
This commit is contained in:
Anna (cybertailor) Vyalkova
2023-03-05 13:26:02 +05:00
parent 7df95c2f2d
commit d5e6409965
2 changed files with 65 additions and 40 deletions
Download Patch File Download Diff File Expand all files Collapse all files

40
dev-python/python-pkcs11/python-pkcs11-0.7.0-r1.ebuild
View File

@@ -1,40 +0,0 @@
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DOCS_BUILDER="sphinx"
DOCS_DIR="${S}/docs"
DOCS_DEPEND="dev-python/sphinx-rtd-theme"
PYTHON_COMPAT=( python3_{8..10} )
inherit distutils-r1 docs
DESCRIPTION="PKCS#11 (Cryptoki) support for Python"
HOMEPAGE="
https://github.com/danni/python-pkcs11
https://pypi.org/project/python-pkcs11/
"
SRC_URI="mirror://pypi/${P:0:1}/${PN}/${P}.tar.gz"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~x86"
#hardware device needed for tests
RESTRICT="test"
RDEPEND="
>=dev-python/asn1crypto-1.0.0[${PYTHON_USEDEP}]
dev-python/cached-property[${PYTHON_USEDEP}]
"
DEPEND="
${RDEPEND}
dev-python/cython[${PYTHON_USEDEP}]
test? (
dev-python/cryptography[${PYTHON_USEDEP}]
dev-python/oscrypto[${PYTHON_USEDEP}]
dev-python/parameterized[${PYTHON_USEDEP}]
)
"
distutils_enable_tests pytest

65
dev-python/python-pkcs11/python-pkcs11-0.7.0-r2.ebuild Normal file
View File

@@ -0,0 +1,65 @@
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{9..11} )
DISTUTILS_USE_PEP517=setuptools
PYPI_NO_NORMALIZE=1
inherit edo distutils-r1 pypi
DESCRIPTION="PKCS#11 (Cryptoki) support for Python"
HOMEPAGE="
https://pypi.org/project/python-pkcs11/
https://github.com/danni/python-pkcs11
"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~x86"
RDEPEND="
>=dev-python/asn1crypto-1.0.0[${PYTHON_USEDEP}]
dev-python/cached-property[${PYTHON_USEDEP}]
"
BDEPEND="
dev-python/cython[${PYTHON_USEDEP}]
dev-python/setuptools-scm[${PYTHON_USEDEP}]
test? (
dev-libs/openssl
dev-libs/softhsm
dev-python/cryptography[${PYTHON_USEDEP}]
dev-python/oscrypto[${PYTHON_USEDEP}]
dev-python/parameterized[${PYTHON_USEDEP}]
)
"
distutils_enable_tests pytest
distutils_enable_sphinx docs
python_test() {
cd "${S}" || die
epytest
}
src_test() {
local -x PKCS11_MODULE="${BROOT}/usr/$(get_libdir)/softhsm/libsofthsm2.so"
local -x PKCS11_TOKEN_LABEL="TEST"
local -x PKCS11_TOKEN_PIN="1234"
local -x PKCS11_TOKEN_SO_PIN="5678"
mkdir -p "${HOME}/.config/softhsm2" || die
cat > "${HOME}/.config/softhsm2/softhsm2.conf" <<- EOF || die "Failed to create config"
directories.tokendir = ${T}
objectstore.backend = file
EOF
edo softhsm2-util --init-token --free \
--label ${PKCS11_TOKEN_LABEL} \
--pin ${PKCS11_TOKEN_PIN} \
--so-pin ${PKCS11_TOKEN_SO_PIN}
rm -r pkcs11 || die
distutils-r1_src_test
}