dev-cpp/usockets: tiny, ultra fast, async sockets framework

Package-Manager: Portage-2.3.89, Repoman-2.3.20
Signed-off-by: Aisha Tammy <gentoo@aisha.cc>

dev-cpp/usockets/usockets-0.3.5.ebuild

@@ -0,0 +1,48 @@
+# Copyright 2019-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit multilib
+
+DESCRIPTION="tiny eventing, networking & crypto for async applications"
+HOMEPAGE="https://github.com/uNetworking/uSockets"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/uNetworking/uSockets.git"
+else
+	SRC_URI="https://github.com/uNetworking/uSockets/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm64 ~x86"
+	S="${WORKDIR}/uSockets-${PV}"
+fi
+
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="libuv +ssl libressl debug"
+
+DEPEND="ssl? (
+			  libressl? ( >=dev-libs/libressl-3.0.0 )
+			  !libressl? ( >=dev-libs/openssl-1.1.0 )
+			  )
+	libuv? ( dev-libs/libuv )
+"
+BDEPEND="${DEPEND}"
+RDEPEND="${DEPEND}"
+
+PATCHES=(
+	"${FILESDIR}/usockets-Makefile.patch"
+)
+
+src_compile() {
+	# the Makefile uses environment variables
+	emake WITH_OPENSSL=$(usex ssl 1 0) \
+		  WITH_LIBUV=$(usex libuv 1 0) \
+		  WITH_ASAN=$(usex debug 1 0) \
+		  default
+}
+
+src_install() {
+	emake libdir="/usr/$(get_libdir)" prefix="/usr" DESTDIR="${D}" install
+	einstalldocs
+}