dev-python/dockerflow: new package, add 2026.3.4

Signed-off-by: Katalin Rebhan <kat@knifepoint.net>

dev-python/dockerflow/Manifest

@@ -0,0 +1 @@
+DIST dockerflow-2026.3.4.gh.tar.gz 61315 BLAKE2B f79a253648fadf499ed7271adaf85b97cb76b80b094235efc5e2a8c97183a02cf578730432fbf4ce6038b2d7ec41a4a3ce4dfc1e22fbff3f49b508ca0000b7b5 SHA512 133d69ab3c8e79ed9fd418c5e42d234cefe25e4899ab306bfcbe9082afd28107f44c4bb5bd6b100d91d1b4444c169366aaf31ecfcc05d96450d686c7afcf450f

dev-python/dockerflow/dockerflow-2026.3.4.ebuild

@@ -0,0 +1,78 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{12..15} )
+DISTUTILS_USE_PEP517=setuptools
+
+inherit distutils-r1
+
+MY_TAG_NAME="$(printf '%4d.%02d.%02d' ${PV//./ })"
+
+DESCRIPTION="Python tools and helpers for Mozilla's Dockerflow"
+HOMEPAGE="
+	https://github.com/mozilla-services/python-dockerflow
+	https://pypi.org/project/dockerflow/"
+SRC_URI="https://github.com/mozilla-services/python-dockerflow/archive/${MY_TAG_NAME}.tar.gz -> ${P}.gh.tar.gz"
+
+S="${WORKDIR}/python-dockerflow-${MY_TAG_NAME}"
+
+LICENSE="MPL-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+
+BDEPEND="
+	test? (
+		dev-db/redis
+		dev-python/redis[${PYTHON_USEDEP}]
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/fakeredis[${PYTHON_USEDEP}]
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+		dev-python/django[${PYTHON_USEDEP}]
+		dev-python/django-redis[${PYTHON_USEDEP}]
+		dev-python/fastapi[${PYTHON_USEDEP}]
+		dev-python/asgiref[${PYTHON_USEDEP}]
+		dev-python/flask[${PYTHON_USEDEP}]
+		dev-python/flask-login[${PYTHON_USEDEP}]
+		dev-python/blinker[${PYTHON_USEDEP}] )"
+
+EPYTEST_PLUGINS=( pytest-{mock,cov,django} )
+EPYTEST_IGNORE=(
+	# sanic not packaged
+	tests/sanic/test_sanic.py
+	# flask-migrate not packaged
+	tests/flask/test_flask.py )
+EPYTEST_DESELECT=(
+	# I don't know what's going on with these
+	tests/django/test_django.py::test_error_returns_500_and_logs_error
+	tests/fastapi/test_fastapi.py::test_mozlog_without_correlation_id_middleware
+	tests/fastapi/test_fastapi.py::test_error_returns_500_and_logs_error)
+distutils_enable_tests pytest
+
+src_compile() {
+	export SETUPTOOLS_SCM_PRETEND_VERSION_FOR_DOCKERFLOW=${PV}
+	distutils-r1_src_compile
+}
+
+python_test() {
+	# Tests expect a running redis server, so let's provide it
+	exec 3< <(redis-server /dev/null)
+	local redis_pid=$!
+
+	# Wait until it's ready
+	while IFS= read -r line <&3 || die "failed to start redis server"; do
+		echo "$line"
+		[[ "$line" =~ "Ready to accept connections" ]] && break
+	done
+	cat <&3 &
+
+	local -x DJANGO_SETTINGS_MODULE=tests.django.settings
+	nonfatal epytest
+	local epytest_result=$?
+
+	kill -INT $redis_pid
+	wait $redis_pid
+
+	(( epytest_result == 0 )) || die "pytest failed with ${EPYTHON}"
+}

dev-python/dockerflow/metadata.xml

@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<name>Katalin Rebhan</name>
+		<email>kat@knifepoint.net</email>
+	</maintainer>
+	<upstream>
+		<remote-id type="pypi">dockerflow</remote-id>
+		<remote-id type="github">mozilla-services/python-dockerflow</remote-id>
+	</upstream>
+</pkgmetadata>