app-text/libspelling: new package, add 0.2.0

Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo@sysrq.in>

app-text/libspelling/Manifest

@@ -0,0 +1 @@
+DIST libspelling-0.2.0.tar.bz2 45591 BLAKE2B 5fefe443d9f492d1d84e41eaba74065eab8a0b1d62b5bb292f221b4af02832dc0114d801cd08e6b9ef3c905f27da524f3331b64e7726e8138e665dfd512ac7ab SHA512 3eef6fe3d0ed32d2c7a8da7eab337b4553d5f4dd0a3c3b24dcf3036d4c1218411122bfec3842160581a669e049bee7f3e3c1b86a03cc1de67ae30bb9cab0584f

app-text/libspelling/libspelling-0.2.0.ebuild

@@ -0,0 +1,59 @@
+# Copyright 2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson vala
+
+DESCRIPTION="A GNOME library for spellchecking"
+HOMEPAGE="https://gitlab.gnome.org/chergert/libspelling"
+SRC_URI="https://gitlab.gnome.org/chergert/${PN}/-/archive/${PV}/${P}.tar.bz2"
+
+LICENSE="LGPL-2.1+"
+SLOT="1"
+KEYWORDS="~amd64"
+IUSE="+enchant gtk-doc vala"
+
+RDEPEND="
+	dev-libs/glib:2
+	>=gui-libs/gtk-4.8:4
+	>=gui-libs/gtksourceview-5.6:5
+	enchant? (
+		app-text/enchant:2
+		dev-libs/icu:=
+	)
+"
+DEPEND="${RDEPEND}
+	vala? (
+		$(vala_depend)
+		>=gui-libs/gtksourceview-5.6:5[vala]
+	)
+"
+BDEPEND="
+	dev-libs/gobject-introspection
+	virtual/pkgconfig
+	gtk-doc? ( dev-util/gi-docgen )
+"
+
+src_prepare() {
+	use vala && vala_setup
+	default
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature enchant)
+		$(meson_use gtk-doc docs)
+		$(meson_use vala vapi)
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	if use gtk-doc; then
+		mkdir -p "${ED}"/usr/share/gtk-doc/html/ || die
+		mv "${ED}"/usr/share/doc/${PN}-${SLOT} "${ED}"/usr/share/gtk-doc/html/ || die
+	fi
+}

app-text/libspelling/metadata.xml

@@ -0,0 +1,15 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>cyber+gentoo@sysrq.in</email>
+		<name>Anna</name>
+	</maintainer>
+	<upstream>
+		<doc>https://chergert.pages.gitlab.gnome.org/libspelling/libspelling-1/</doc>
+		<remote-id type="gnome-gitlab">chergert/libspelling</remote-id>
+	</upstream>
+	<use>
+		<flag name="enchant">Enable spellchecking using <pkg>app-text/enchant</pkg></flag>
+	</use>
+</pkgmetadata>