media-libs/monado: add 25.0.0

Signed-off-by: Haelwenn (lanodan) Monnier <contact@hacktivis.me>

media-libs/monado/Manifest

@@ -0,0 +1 @@
+DIST monado-v25.0.0.tar.gz 5066893 BLAKE2B 2e05e58cda98c4e02b9db61c387c649d550c39b6edaadc9a76a2dd5105d24b7abac3d4b349c1786c8cfcdd5349ace19193057b987961194a9785f32925db0ed6 SHA512 9787aec697ef94b0b4c17cc440a0799ab347d1f692a8f886fb32999300af0a86a036eec3225f12f2c901f34f03a581bd9aea6e4e4f4c3a8bc63dff4f639a7037

media-libs/monado/monado-25.0.0.ebuild

@@ -0,0 +1,102 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake
+
+DESCRIPTION="The open source OpenXR runtime."
+HOMEPAGE="https://monado.dev"
+
+if [[ "${PV}" = *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://gitlab.freedesktop.org/monado/monado.git"
+else
+	SRC_URI="https://gitlab.freedesktop.org/monado/monado/-/archive/v${PV}/monado-v${PV}.tar.gz"
+	S="${WORKDIR}/monado-v${PV}/"
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="Boost-1.0"
+SLOT="0"
+
+IUSE="dbus gles gstreamer onnxruntime opencv opengl psvr sdl systemd uvc vive vulkan wayland X"
+
+# TODO: OpenHMD, percetto?, libsurvive?
+DEPEND="
+	media-libs/openxr-loader
+	media-libs/mesa[egl(+)]
+	dev-cpp/eigen:3
+	dev-util/glslang
+	virtual/libusb:=
+	virtual/libudev
+	media-libs/libv4l
+	dev-libs/libbsd
+	dev-libs/cJSON
+	wayland? (
+		dev-libs/wayland
+		dev-libs/wayland-protocols
+		dev-util/wayland-scanner
+	)
+	X? (
+		x11-libs/libX11
+		x11-libs/libXrandr
+		x11-libs/libxcb
+	)
+	vulkan? (
+		media-libs/vulkan-loader
+		dev-util/vulkan-headers
+	)
+	opengl? ( virtual/opengl )
+	opencv? ( media-libs/opencv:= )
+	gles? ( media-libs/mesa[gles1,gles2] )
+	dbus? ( sys-apps/dbus )
+	systemd? ( sys-apps/systemd:= )
+	uvc? ( media-libs/libuvc )
+	sdl? ( media-libs/libsdl2 )
+	gstreamer? ( media-libs/gstreamer )
+	psvr? ( dev-libs/hidapi )
+	vive? ( sys-libs/zlib:= )
+	onnxruntime? ( sci-libs/onnxruntime )
+"
+RDEPEND="${DEPEND}"
+
+src_configure() {
+	local mycmakeargs=(
+		-DXRT_HAVE_WAYLAND=$(usex wayland)
+		-DXRT_HAVE_XLIB=$(usex X)
+		-DXRT_HAVE_XRANDR=$(usex X)
+		-DXRT_HAVE_XCB=$(usex X)
+
+		-DXRT_HAVE_VULKAN=$(usex vulkan)
+		-DXRT_HAVE_OPENGL=$(usex opengl)
+		-DXRT_HAVE_OPENGLES=$(usex gles)
+		-DXRT_HAVE_EGL=ON
+		-DXRT_HAVE_LIBBSD=ON
+		-DXRT_HAVE_SYSTEMD=$(usex systemd)
+		-DXRT_INSTALL_SYSTEMD_UNIT_FILES=$(usex systemd)
+
+		-DXRT_HAVE_LIBUSB=ON
+		-DXRT_HAVE_JPEG=ON
+		-DXRT_HAVE_OPENCV=$(usex opencv)
+		-DXRT_HAVE_LIBUVC=$(usex uvc)
+		-DXRT_HAVE_SDL2=$(usex sdl)
+		-DXRT_HAVE_SYSTEM_CJSON=ON
+		-DXRT_HAVE_GST=$(usex gstreamer)
+		-DXRT_HAVE_PERCETTO=OFF
+
+		-DXRT_BUILD_DRIVER_PSVR=$(usex psvr)
+		-DXRT_BUILD_DRIVER_VIVE=$(usex vive)
+		-DXRT_BUILD_DRIVER_OHMD=OFF
+		-DXRT_BUILD_DRIVER_HANDTRACKING=$(usex onnxruntime)
+		-DXRT_BUILD_DRIVER_DAYDREAM=$(usex dbus)
+		-DXRT_BUILD_DRIVER_ARDUINO=$(usex dbus)
+		-DXRT_BUILD_DRIVER_ILLIXR=OFF
+		-DXRT_BUILD_DRIVER_ULV2=OFF
+
+		-DXRT_BUILD_DRIVER_SURVIVE=OFF
+		-DXRT_BUILD_DRIVER_QWERTY=$(usex sdl)
+	)
+
+	cmake_src_configure
+}

media-libs/monado/monado-9999.ebuild

@@ -3,16 +3,24 @@
 
 EAPI=7
 
-# CMake picked to avoid automagic dependencies in meson.build
-inherit cmake git-r3
+inherit cmake
 
 DESCRIPTION="The open source OpenXR runtime."
 HOMEPAGE="https://monado.dev"
-EGIT_REPO_URI="https://gitlab.freedesktop.org/monado/monado.git"
+
+if [[ "${PV}" = *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://gitlab.freedesktop.org/monado/monado.git"
+else
+	SRC_URI="https://gitlab.freedesktop.org/monado/monado/-/archive/v${PV}/monado-v${PV}.tar.gz"
+	S="${WORKDIR}/monado-v${PV}/"
+	KEYWORDS="~amd64"
+fi
+
 LICENSE="Boost-1.0"
 SLOT="0"
 
-IUSE="dbus ffmpeg gles gstreamer onnxruntime opencv opengl psvr sdl systemd uvc vive vulkan wayland X"
+IUSE="dbus gles gstreamer onnxruntime opencv opengl psvr sdl systemd uvc vive vulkan wayland X"
 
 # TODO: OpenHMD, percetto?, libsurvive?
 DEPEND="
@@ -45,7 +53,6 @@ DEPEND="
 	dbus? ( sys-apps/dbus )
 	systemd? ( sys-apps/systemd:= )
 	uvc? ( media-libs/libuvc )
-	ffmpeg? ( media-video/ffmpeg:= )
 	sdl? ( media-libs/libsdl2 )
 	gstreamer? ( media-libs/gstreamer )
 	psvr? ( dev-libs/hidapi )
@@ -67,20 +74,18 @@ src_configure() {
 		-DXRT_HAVE_EGL=ON
 		-DXRT_HAVE_LIBBSD=ON
 		-DXRT_HAVE_SYSTEMD=$(usex systemd)
-		-DXRT_INSTALL_SYSTEMD_UNIT_FILES=ON
+		-DXRT_INSTALL_SYSTEMD_UNIT_FILES=$(usex systemd)
 
 		-DXRT_HAVE_LIBUSB=ON
 		-DXRT_HAVE_JPEG=ON
 		-DXRT_HAVE_OPENCV=$(usex opencv)
 		-DXRT_HAVE_LIBUVC=$(usex uvc)
-		-DXRT_HAVE_FFMPEG=$(usex ffmpeg)
 		-DXRT_HAVE_SDL2=$(usex sdl)
 		-DXRT_HAVE_SYSTEM_CJSON=ON
 		-DXRT_HAVE_GST=$(usex gstreamer)
 		-DXRT_HAVE_PERCETTO=OFF
 
 		-DXRT_BUILD_DRIVER_PSVR=$(usex psvr)
-		-DXRT_BUILD_DRIVER_RS=OFF
 		-DXRT_BUILD_DRIVER_VIVE=$(usex vive)
 		-DXRT_BUILD_DRIVER_OHMD=OFF
 		-DXRT_BUILD_DRIVER_HANDTRACKING=$(usex onnxruntime)