diff --git a/dev-python/pytest-harvest/pytest-harvest-1.10.5-r1.ebuild b/dev-python/pytest-harvest/pytest-harvest-1.10.5-r1.ebuild
new file mode 100644
index 0000000000..0625e09cb9
--- /dev/null
+++ b/dev-python/pytest-harvest/pytest-harvest-1.10.5-r1.ebuild
@@ -0,0 +1,47 @@
+# Copyright 2022-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{12..14} )
+DISTUTILS_USE_PEP517=setuptools
+PYPI_NO_NORMALIZE=1
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Store and retrieve data created during your pytest tests execution"
+HOMEPAGE="
+	https://pypi.org/project/pytest-harvest/
+	https://github.com/smarie/python-pytest-harvest
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	dev-python/decopatch[${PYTHON_USEDEP}]
+	>=dev-python/makefun-1.5[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/setuptools-scm[${PYTHON_USEDEP}]
+	test? (
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pandas[${PYTHON_USEDEP}]
+		dev-python/tabulate[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGIN_LOAD_VIA_ENV=1
+EPYTEST_PLUGINS=( ${PN} pytest-cases pytest-xdist )
+EPYTEST_DESELECT=(
+	"pytest_harvest/tests/test_all_raw_with_meta_check.py::test_run_all_tests[test_get_session_results.py]"
+	"pytest_harvest/tests/test_all_raw_with_meta_check.py::test_run_all_tests[test_get_session_results_indirect_and_noparam.py]"
+)
+
+distutils_enable_tests pytest
+
+python_test() {
+	epytest pytest_harvest/tests --doctest-modules
+}