dev-libs/aws-c-io: add 0.19.1

Signed-off-by: KotoishiHeart <trakrailysurely@danceylove.net>
Part-of: https://github.com/gentoo/guru/pull/331
Signed-off-by: KotoishiHeart <trakrailysurely@danceylove.net>

dev-libs/aws-c-io/Manifest

@@ -0,0 +1 @@
+DIST aws-c-io-0.19.1.tar.gz 736276 BLAKE2B 66afe228fda5d24eb240f9c187bfe5516fa81c8206089813b35ac7872ff5592d9014e1e7b0ae805ead59953d56abbce0356b41b7618d180f292a36c37dfb1d90 SHA512 980de4a052155226ff71e6c3a0e5b49c2717b6bf8478148b327963d6a6856b81940f0d9fa3cdaa9e99606f39e93fb74bee601b4f03e2d0f285b0f0056277fdce

dev-libs/aws-c-io/aws-c-io-0.19.1.ebuild

@@ -0,0 +1,41 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="AWS SDK for C module, handles IO and TLS work for application protocols"
+HOMEPAGE="https://github.com/awslabs/aws-c-io"
+SRC_URI="https://github.com/awslabs/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="test"
+
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	dev-libs/aws-c-common:=
+	dev-libs/aws-c-cal:=
+	dev-libs/s2n:=
+"
+RDEPEND="${DEPEND}"
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_TESTING=$(usex test)
+	)
+
+	if use test; then
+		# (#759802) Due to network sandboxing of portage, internet connectivity
+		# tests will always fail. If you need a USE flag, because you want/need
+		# to perform these tests manually, please open a bug report for it.
+		mycmakeargs+=(
+			-DENABLE_NET_TESTS=OFF
+		)
+	fi
+
+	cmake_src_configure
+}

dev-libs/aws-c-io/metadata.xml

@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="person">
+    <email>trakrailysurely@danceylove.net</email>
+    <name>Okamura Kazuya</name>
+  </maintainer>
+  <upstream>
+    <remote-id type="github">awslabs/aws-c-io</remote-id>
+  </upstream>
+</pkgmetadata>