dev-ml/mirage-vnetif: initial import

Signed-off-by: Alessandro Barbieri <lssndrbarbieri@gmail.com>

dev-ml/mirage-vnetif/Manifest

@@ -0,0 +1 @@
+DIST mirage-vnetif-0.6.0.tbz 11787 BLAKE2B 62cace0cc86cb0e167b7604c592907cfc73efbfdb97b82cbdc7957f8c689717df0ae80f6c2a1579d8e11e749f50b5c92ca847d99ca22539df84cf2672191993d SHA512 c3202e2e2d5025d8f71fab8aea60495ad7b2f864d1bee6e0909cde088a8a080305279537b3f412ea3050dc35b4e39ce224e34a0c6b944f80c7d28a524ef56111

dev-ml/mirage-vnetif/metadata.xml

@@ -0,0 +1,14 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="person">
+    <email>lssndrbarbieri@gmail.com</email>
+    <name>Alessandro Barbieri</name>
+  </maintainer>
+  <upstream>
+    <remote-id type="github">mirage/mirage-vnetif</remote-id>
+  </upstream>
+  <use>
+    <flag name="stack">Vnetif implementation of mirage-stack for Mirage TCP/IP</flag>
+  </use>
+</pkgmetadata>

dev-ml/mirage-vnetif/mirage-vnetif-0.6.0.ebuild

@@ -0,0 +1,56 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit dune multiprocessing
+
+DESCRIPTION="Virtual network interface and software bridge for Mirage"
+HOMEPAGE="https://github.com/mirage/mirage-vnetif"
+SRC_URI="https://github.com/mirage/${PN}/releases/download/v${PV}/${P}.tbz"
+
+LICENSE="ISC"
+SLOT="0/${PV}"
+KEYWORDS="~amd64"
+IUSE="ocamlopt stack test"
+
+RDEPEND="
+	dev-ml/result
+	dev-ml/lwt
+	dev-ml/mirage-net
+	dev-ml/cstruct
+	dev-ml/ipaddr
+	dev-ml/mirage-profile
+	dev-ml/duration
+	dev-ml/logs
+
+	stack? (
+		dev-ml/mirage-time
+		dev-ml/mirage-clock
+		dev-ml/mirage-random
+		dev-ml/tcpip
+		dev-ml/ethernet
+		dev-ml/arp
+	)
+"
+DEPEND="
+	${RDEPEND}
+	test? (
+		dev-ml/alcotest
+		dev-ml/mirage-random-test
+	)
+"
+
+RESTRICT="!test? ( test )"
+REQUIRED_USE="test? ( stack )"
+
+src_compile() {
+	local pkgs="mirage-vnetif"
+	use stack && pkgs="${pkgs},mirage-vnetif-stack"
+	dune build --only-packages "${pkgs}" -j $(makeopts_jobs) --profile release || die
+}
+
+src_install() {
+	dune_src_install mirage-vnetif
+	use stack && dune_src_install mirage-vnetif-stack
+}